Daten aus aktiver Zeile in andere Datei

Forumthread: Daten aus aktiver Zeile in andere Datei

24.05.2008 17:51:43

Andres

Hallo,
kann mir jemand weiterhelfen.
Ich habe eine große Datei Teilnehmer.xls mit vielen Datensätzen.
Ich benötige ein Makro, welches mir ermöglicht, dass wenn ich
auf irgendeiner Zeile in der Spalte A (Teilnehmername) stehe,
durch Tastendruck einer markanten Taste (z.B. eine Funktionstaste o.ä.)
sich eine eigene bereits bestehende Datei Urkunde.xls zur weiteren Bearbeitung öffnet und
Daten aus der aktiven Zeile (z.B. Spalte D, F, H) der Datei Teilnehmer.xls
in die neue Datei (z.B. in Feld B2, C2, D2) übernimmt und
als Datei mit der Bezeichnung Urkunde_ [Teilnehmername] .xls speichert.
Kann mir hier vielleicht jemand weiterhelfen.
Gruß
Andres

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Daten aus aktiver Zeile in andere Datei

24.05.2008 18:39:37

Josef

Hallo Andres,
diesen Code in das Modul der Tabelle.
Mit Doppelklick in Spalte "A" wird das Makro gestartet.
' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim objWB As Workbook, strName As String

Const cstrUrkunde As String = "C:\Pfad Zur Urkunde\urkunde.xls" 'Pfad und Name der Urkunde - Anpassen!
Const cstrPath As String = "C:\Urkunden\" 'Pfad unter dem die Urkunden gespeichert werden sollen - Anpassen!

On Error GoTo ErrExit

Application.ScreenUpdating = False

If Target.Column = 1 And Target.Row > 1 And Target <> "" Then
    Cancel = True

    strName = Target.Text & ".xls"

    Set objWB = Workbooks.Open(cstrUrkunde)

    With objWB.Sheets(1)
        .Range("B2") = Target.Offset(0, 3).Text 'Text aus Spalte "D" in Zelle "B2"
        .Range("C2") = Target.Offset(0, 5).Text 'Text aus Spalte "F" in Zelle "C2"
        .Range("D2") = Target.Offset(0, 7).Text 'Text aus Spalte "H" in Zelle "D2"
    End With

    objWB.SaveAs cstrPath & IIf(Right(cstrPath, 1) <> "\", "\", "") & strName
    objWB.Close

    MsgBox "Urkunde wurde als" & Space(45) & vbLf & vbLf & cstrPath & _
        IIf(Right(cstrPath, 1) <> "\", "\", "") & strName & vbLf & vbLf & _
        "gespeichert!", vbInformation, "Urkunde"
End If

ErrExit:

If Err.Number > 0 Then
    MsgBox Err.Number & vbLf & Err.Description, vbExclamation, "Fehler"
End If

Application.ScreenUpdating = True
Set objWB = Nothing
End Sub

Gruß Sepp

AW: Daten aus aktiver Zeile in andere Datei

24.05.2008 20:27:00

andres

Hallo Sepp,
genial.
Es funktioniert bei mir.
Vielen Dank.
Gruß
Andres

AW: Daten aus aktiver Zeile in andere Datei

24.05.2008 22:12:01

andres

Hallo Sepp,
genial.
Es funktioniert bei mir.
Vielen Dank.
Gruß
Andres

Beliebteste Forumthreads (12 Monate)

Daten aus aktiver Zeile in andere Datei

Forumthread: Daten aus aktiver Zeile in andere Datei

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Daten aus aktiver Zeile in andere Datei

Forumthread: Daten aus aktiver Zeile in andere Datei

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread