Microsoft Excel

Herbers Excel/VBA-Archiv

Daten aus bestimmter Zeile | Herbers Excel-Forum


Betrifft: Daten aus bestimmter Zeile von: liese
Geschrieben am: 13.11.2009 17:56:35

Hallo!

Suche mal wieder Hilfe.
Habe Daten im Bereich z.B. A1:F100
In der Spalte A stehen Datumswerte formatiert als TTMM.
(Gleiche Datumswerte können mehrfach vorkommen)
Nun möchte ich gerne in einer anderen Tabelle nur die
Zeilen angezeigt bekommen, die dem heutigen Datum
entsprechen, also der Vergleich mit TTMM.

Viele Grüße
Anneliese

  

Betrifft: AW: Daten aus bestimmter Zeile von: IngGi
Geschrieben am: 13.11.2009 18:20:59

Hallo Anneliese,

die Formel in A13 kannst du einfach runter- und nach rechts kopieren. Achtung - es handelt sich um eine Matrixformel. Bitte unbedingt den untenstehenden Hinweis beachten. Die Formel muss allerdings noch auf deine Tabellenstruktur angepasst werden. An den Stellen, an denen eine 1 abgezogen wird, geschieht dies, weil die erste Datenzeile in der Quelltabelle nicht die Zeile 1, sondern die Zeile 2 ist. Das wird eben mit -1 korrigiert.

 ABCDEF
1Quelltabelle
213.11.2009ABCDE
314.11.2009ABCDE
413.11.2009ABCDE
514.11.2009ABCDE
613.11.2009ABCDE
714.11.2009ABCDE
813.11.2009ABCDE
914.11.2009ABCDE
1013.11.2009ABCDE
11      
12Zieltabelle
1313.11.2009ABCDE
1413.11.2009ABCDE
1513.11.2009ABCDE
1613.11.2009ABCDE
1713.11.2009ABCDE
18      
19      
20      
21      
22      

Formeln der Tabelle
ZelleFormel
A13{=WENN(ISTFEHLER(INDEX(A$2:A$10;KKLEINSTE(WENN($A$2:$A$10=HEUTE();ZEILE($A$2:$A$10)-1);ZEILE(A1))));"";INDEX(A$2:A$10;KKLEINSTE(WENN($A$2:$A$10=HEUTE();ZEILE($A$2:$A$10)-1);ZEILE(A1))))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

Gruß Ingolf


  

Betrifft: AW: Daten aus bestimmter Zeile von: Josef Ehrensberger
Geschrieben am: 13.11.2009 18:25:13

Hallo Anneliese,

die Formel kannst du nach unten und rechts kopieren.

Tabelle3

 ABC
113.11.2009Wert1Wert2
2 4d
3 5e
4 6f
5   

Formeln der Tabelle
ZelleFormel
B2{=WENN(ZEILE(A1)>ZÄHLENWENN(Tabelle2!$A$2:$A$1000;$A$1); "";INDEX(Tabelle2!B$2:B$1000;KKLEINSTE(WENN(Tabelle2!$A$2:$A$1000=$A$1;ZEILE($1:$999)); ZEILE(A1))))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Tabelle2

 ABC
1DatumWert1Wert2
210.11.20091a
310.11.20092b
412.11.20093c
513.11.20094d
613.11.20095e
713.11.20096f
8   
9   


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4




Gruß Sepp



  

Betrifft: AW an Ingo u. Josef von: liese
Geschrieben am: 13.11.2009 23:13:20

Hallo Ihr Beiden!

Bin bis jetzt mit der Umsetzung nicht klar gekommen.
Vielleicht noch mal kurz.
Bezgl. der Daten in Tab1 sollen in Tab2 Zeilen ausgegeben werden.
Der Vergleich soll abgeglichen werden mit TTMM von Tab1 Spalte A
mit dem heutigen Datum, aber nur mit TTMM.
Ich hoffe, das ist verständlich.
Danke für weitere Hilfe.

Viele Grüße
Anneliese


  

Betrifft: AW: AW an Ingo u. Josef von: Josef Ehrensberger
Geschrieben am: 14.11.2009 06:13:25

Hallo Anneliese,

meinst du so?

Tabelle2

 AB
1Wert1Wert2
29i
310j

Formeln der Tabelle
ZelleFormel
A2{=WENN(ZEILE(A1)>SUMMENPRODUKT((TAG(Tabelle1!$A$2:$A$1000)=TAG(HEUTE()))*(MONAT(Tabelle1!$A$2:$A$1000)=MONAT(HEUTE()))); "";INDEX(Tabelle1!B$2:B$1000;KKLEINSTE(WENN((TAG(Tabelle1!$A$2:$A$1000)=TAG(HEUTE()))*(MONAT(Tabelle1!$A$2:$A$1000)=MONAT(HEUTE())); ZEILE($1:$999)); ZEILE(A1))))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Tabelle1

 ABC
1DatumWert1Wert2
210.11.20081a
310.11.20092b
411.11.20083c
511.11.20094d
612.11.20085e
712.11.20096f
813.11.20087g
913.11.20098h
1014.11.20099i
1114.11.200910j


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4




Gruß Sepp



  

Betrifft: AW: AW an Ingo u. Josef von: liese
Geschrieben am: 14.11.2009 11:09:22

Hallo Jo"Sepp" ;-)

Eine wunderbare Formel, die ich überhaupt nicht verstehe,
die aber hervorragend funktioniert.
Wenn ich noch einen kleinen Anpassungswunsch loswerden
darf?
Wenn in der Spalte A der Tab1 die Jahreszahl von der aktuellen
abweicht und in Zellen rechts daneben nichts steht, wird
00.01.1900 ausgegeben. Kann man das noch unterdrücken?

Viele Grüße
Anneliese


  

Betrifft: AW: AW an Ingo u. Josef von: liese
Geschrieben am: 14.11.2009 11:16:50

Hallo Sepp!

Gerade bemerkt:
Wenn in den Zellen der Tab1 in den Spalten B bis xyz
Zahlen stehen, werden die als Datum interpretiert.
Kann man das noch neutralisieren?

Viele Grüße
Anneliese


  

Betrifft: AW: AW an Ingo u. Josef von: liese
Geschrieben am: 14.11.2009 11:24:26

Sorry, noch eine Feststellung:

Wenn ich die Arrayformel in einer Tabelle in einer
x-beliebigen Zellen einsetze, werden Zahlen jetzt
nicht als Datum, sondern korrekt dargestellt???
Leere Zellen werden mit 0 dargestellt???

Viele Grüße
Anneliese


  

Betrifft: AW: AW an Ingo u. Josef von: Josef Ehrensberger
Geschrieben am: 14.11.2009 11:54:52

Hallo Liese,

das iegt ausschliesslich an der Zellformatierung,
formatiere die Zellen mit dem Benutzerdefinierten Format "Standard;-Standard;;", dann werden Nullwerte nicht angezeigt.


Gruß Sepp



  

Betrifft: AW: Josef (klappt) von: liese
Geschrieben am: 14.11.2009 13:52:09

Hallo Sepp!

Habe die Formateinstellungen geändert.
Alles klappt jetzt bestens.
Nochmals ganz herzlichen Dank für die Hilfe.

Viele Grüße
Anneliese


  

Betrifft: hier noch eine Version... von: Tino
Geschrieben am: 14.11.2009 12:23:19

Hallo,
die Leerzellen überspringt.
Die Ergebniszellen musst Du danach nur richtig Formatieren um die gewünschte anzeige zu bekommen.

Formel nach unten und 5 Spalten nach rechts ziehen.

Tabelle2

 B
240131

Formeln der Tabelle
ZelleFormel
B2{=WENN(ZEILE($A1)>SUMMENPRODUKT((TAG(Tabelle1!$A$1:$A$100)=TAG(HEUTE()))*(MONAT(Tabelle1!$A$1:$A$100)=MONAT(HEUTE()))); "";INDEX(Tabelle1!$A$1:$F$100;KKLEINSTE(WENN((TAG(Tabelle1!$A$1:$A$100)=TAG(HEUTE()))*(MONAT(Tabelle1!$A$1:$A$100)=MONAT(HEUTE())); ZEILE($1:$100)); ZEILE($A1)); SPALTE(A$1)))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Gruß Tino


  

Betrifft: AW: hier noch eine Version... von: liese
Geschrieben am: 14.11.2009 13:57:59

Hallo Tino!

Habe Deine Formel ausprobiert, bekomme aber die
Fehlermeldung #WERT!
Aber nicht schlimm da es ja mit Jo"Sepp"s Lösung nun
hervorragend funktioniert.
Danke aber auch an Dich für Deinen Aufwand.
Schön, dass hier Hilfe angeboten wird.

Viele Grüße
Anneliese


  

Betrifft: hier die Beispieldatei... von: Tino
Geschrieben am: 14.11.2009 14:24:40

Hallo,

https://www.herber.de/bbs/user/65899.xls

Gruß Tino


Beiträge aus den Excel-Beispielen zum Thema "Daten aus bestimmter Zeile"