Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Kommentar zu Zelle per VBA

Kommentar zu Zelle per VBA
heidi
Hallo VBA-Profis,
ich habe folgendes Makro aufgenommen, doch es läuft anschließend nicht, bleibt in Zeile:
Selection.ShapeRange.ScaleHeight 2.39, msoFalse, msoScaleFromTopLeft
stehen mit der Fehlermeldung: Laufzeitfehler 438: Objekt unterstützt diese Eigenschaft nicht.
Hier meine zwei Fragen:
1. Wie muss ich es schreiben, damit ich die Größe des Kommentarfeldes in die Länge ziehen kann und der ganze Kommentar zu sehen ist?
2. Am liebsten würde ich Excel per VBA sagen: Such Dir die Zelle mit dem Wert "ReKto" und füge dort folgenden Kommentar ein, damit ich unabhängig davon wäre, in welcher Spalte/Zelle sich dieser Wert aktuell befindet. Wie geht das?
Bereits im Voraus besten Dank für Eure Hilfe.
Grüße,
Heidi
Sub Kommentare()
' Makro6 Fügt den Überschriften Kommentare zum leichteren Verständnis bei.
Range("E1").Select
Range("E1").AddComment
Range("E1").Comment.Visible = False
Range("E1").Comment.Text Text:= _
"ReKto: Rechnungskonto; Existiert nur bei Kunden mit abweichender Rechnungsanschrift  _
oder vorhandenem Hauptdebitor (z. B. Konzerne mit vielen Niederlassungen)"
Selection.ShapeRange.ScaleHeight 2.39, msoFalse, msoScaleFromTopLeft
Selection.ShapeRange.ScaleHeight 0.78, msoFalse, msoScaleFromTopLeft
Range("E1").Select
End Sub

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
Lasse Scale weg u.nimm den Endwert,...
28.02.2011 14:25:36
Luc:-?
…Heidi;
ersetze außerdem Selection.ShapeRange durch Range("E1").Comment. Range("E1").Select kannst du übrigens ganz weg lassen und auch alle Befehle in einer With Range("E1")…End With-Konstruktion zusammen fassen.
Gruß Luc :-?
AW: Kommentar zu Zelle per VBA
28.02.2011 14:31:36
Rudi
Hallo,
etwa so:
Sub xxxx()
Dim rFind As Range
Const sText As String = _
"ReKto: Rechnungskonto; Existiert nur bei Kunden " _
& "mit abweichender Rechnungsanschrift " _
& "oder vorhandenem Hauptdebitor " _
& "(z. B. Konzerne mit vielen Niederlassungen)"
With ActiveSheet
Set rFind = .Cells.Find("ReKto", after:=.Cells(1, 1), lookat:=xlWhole)
End With
If Not rFind Is Nothing Then
If rFind.Comment Is Nothing Then
rFind.AddComment sText
Else
rFind.Comment.Text sText
End If
With rFind.Comment
With .Shape
.Width = 300
.Height = 34
End With
.Visible = False
End With
End If
End Sub

Gruß
Rudi
Anzeige

303 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige