Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema MsgBox
BildScreenshot zu MsgBox MsgBox-Seite mit Beispielarbeitsmappe aufrufen

gehe zu Zelle mit Inhalt (Leer) | Herbers Excel-Forum


Betrifft: gehe zu Zelle mit Inhalt (Leer) von: Hugo
Geschrieben am: 15.01.2010 07:46:30

Guten Morgen allerseits

Wie bringe ich es mittels VBA fertig, dass der Curser von irgendeiner Stelle im Tabellenblatt auf die Zelle in Spalte A springt in welcher (Leer) steht?

Zudem möchte ich, dass anschliessend die enstsprechenden Zellen (mit sämtlichen Inhalten) in Spalten A-G gelöscht werden.

Kann mir jemand weiterhelfen?

Besten Dank im Voraus.

Gruss Hugo

  

Betrifft: AW: gehe zu Zelle mit Inhalt (Leer) von: Tino
Geschrieben am: 15.01.2010 07:55:24

Hallo,
vieleicht geht es hiermit.

Sub GeheZuLeer()
Dim vRow

vRow = Application.Match("Leer", Columns(1), 0)

If IsNumeric(vRow) Then
    Application.Goto Cells(vRow, 1), True
    Cells(vRow, 1).Resize(, 7).ClearContents
Else
    MsgBox "Zelle mit 'Leer' nicht gefunden"
End If

End Sub
Gruß Tino


  

Betrifft: AW: gehe zu Zelle mit Inhalt (Leer) von: Josef Ehrensberger
Geschrieben am: 15.01.2010 08:01:09

Hallo Hugo,

das geht so.


' **********************************************************************
' Modul: Modul2 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub leerWeg()
  Dim rng As Range, rngDel As Range
  Dim strFirst As String
  
  Set rng = Range("A:G").Find(What:="leer", LookAt:=xlPart, LookIn:=xlValues, MatchCase:=False)
  
  If Not rng Is Nothing Then
    strFirst = rng.Address
    
    Do
      
      If rngDel Is Nothing Then
        Set rngDel = rng.EntireRow
      Else
        Set rngDel = Union(rngDel, rng.EntireRow)
      End If
      
      Set rng = Range("A:G").FindNext(rng)
      
    Loop While Not rng Is Nothing And strFirst <> rng.Address
    
  End If
  
  If Not rngDel Is Nothing Then rngDel.Delete
  
  Set rng = Nothing
  Set rngDel = Nothing
End Sub



Gruß Sepp



  

Betrifft: AW: gehe zu Zelle mit Inhalt (Leer) von: Hugo
Geschrieben am: 15.01.2010 08:12:40

Hallo Tino, Hallo Sepp

Besten Dank, beide Lösungen führen zum gewünschten Ergebnis!!

Ich wünsche Euch einen erfolgreichen Tag und ein schönes Wochenende.

Gruss Hugo


Beiträge aus den Excel-Beispielen zum Thema "gehe zu Zelle mit Inhalt (Leer)"