Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1748to1752
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Aus Postleitzahltabelle Orte auslesen

Aus Postleitzahltabelle Orte auslesen
06.04.2020 15:46:17
Stéphane
Hallo miteinander
Lange war es ruhig - aber nun habe ich wieder ein Problem und finde die einfache Lösung nicht:
Ich habe eine Tabelle mit Schweizer Postleitzahlen in der 1. Spalte und den Gemeindenamen in der 2. Spalte in einem separaten Worksheet.
In einem weiteren Worksheet habe ich eine Eingabemaske, u.a. "sitzen" dort 2 Felder:
Im ersten Feld gebe ich die mir bekannte Postleitzahl ein und das 2. Feld gibt mir dann den Ortschaftsnamen zu dieser PLZ.
Dies funktioniert mit einer sverweis Formel gut.
Nun ist aber das Problem, dass es eine PLZ gibt, jedoch zu dieser PLZ 3 verschiedene Ortsnamen existieren. Der obige Lösungsweg zeigt mir dann nur eine Ortschaft.
Mein Ziel wäre es, dass bei diesen einzelnen PLZ ein Feld aufgeht, worin ich den gewünschten Namen per Klick auswählen könnte.
Vielleicht gäbe es auch eine Lösung, dass im 2. Feld der Eingabemaske die Ortschaft manuell überschrieben wird - aber dann würde ja die sverweis Formel gelöscht.
Danke für Eure Hilfe - und hoffentlich geht es euch allen gut, ohne Virus.
Stéphane
https://www.herber.de/bbs/user/136453.xlsx

7
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Aus Postleitzahltabelle Orte auslesen
06.04.2020 16:11:23
Nepumuk
Hallo Stéphane,
Rechtsklick auf den Tabellenreiter - Code anzeigen. In das Codefenster folgende Prozedur einfügen:
Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim objCell As Range
    Dim strFirstAddress As String, strText As String
    Dim blnMultible As Boolean
    If Target.Address = "$F$8" Then
        Application.EnableEvents = False
        Set objCell = Columns(1).Find(What:=Target.Value, LookIn:=xlValues, LookAt:=xlWhole)
        If Not objCell Is Nothing Then
            Call Target.Offset(0, 1).Validation.Delete
            strFirstAddress = objCell.Address
            Do
                strText = strText & "," & objCell.Offset(0, 1).Text
                Set objCell = Columns(1).FindNext(After:=objCell)
                If objCell.Address = strFirstAddress Then Exit Do
                blnMultible = True
            Loop
            If blnMultible Then
                Call Target.Offset(0, 1).Validation.Add(Type:=xlValidateList, Formula1:=Mid$(strText, 2))
                Call MsgBox("Mehrere Fundstellen. Bitte auswählen.", vbInformation, "Information")
                With Target.Offset(0, 1)
                    .Value = Empty
                    Call .Select
                End With
            Else
                Target.Offset(0, 1).Value = Mid$(strText, 2)
            End If
        Else
            Call MsgBox("Postleitzahl nicht gefunden.", vbExclamation, "Hinweis")
            With Target
                .Value = Empty
                Call .Select
            End With
        End If
        Application.EnableEvents = True
    End If
End Sub

Gruß
Nepumuk
Anzeige
AW: Aus Postleitzahltabelle Orte auslesen
06.04.2020 16:25:12
Stéphane
Hallo Nepumuk - grad so aus dem Aermel geschüttelt. Ich bin sprachlos. Dane für Deine Hilfe, ich versuche das gerade mal.
Beste Grüsse
Stéphane
AW: z.B. mit INDEX() und AGGREGAT() ...
06.04.2020 16:11:47
neopa
Hallo Stéphane,
... in J8: =WENNFEHLER(INDEX($B:$B;AGGREGAT(15;6;ZEILE(B2:B999)/($A2:$A999=$I8);SPALTE(A1)));"")
und Formel weit genug nach rechts ziehend kopieren.
Gruß Werner
.. , - ...
AW: z.B. mit INDEX() und AGGREGAT() ...
06.04.2020 16:27:59
Stéphane
HALLO Werner; wiedermal ein ganz grosses Dankeschön. Dies scheint mir die einfachste aber effizienteste Lösung :-).
Beste Grüsse
Stéphane
AW: bitteschön owT
06.04.2020 16:39:27
neopa
Gruß Werner
.. , - ...
AW: Aus Postleitzahltabelle Orte auslesen
06.04.2020 16:16:57
Günther
Moin Stéphane,
eventuell geht das mit einer Formel, aber ich bin kein Formulant ... ;-(
Mit Sicherheit geht das per VBA/Makro.
Und ohne Programmierung kannst du das mit Power Query erreichen, da müsstest du dich einarbeiten. Die Lösung wäre dann beispielsweise eine x-zeilige Tabelle, wo in jeder Zeile in einer Spalte die PLZ und der anderen Spalte der passende Ort steht:
Userbild
Hinweis: Für mich gilt, dass dieser letztgenannte Weg die kostenlose Hilfe zur Selbsthilfe in Foren überschreitet.
Gruß
Günther
Anzeige
AW: Aus Postleitzahltabelle Orte auslesen
06.04.2020 16:23:05
Stéphane
Hallo Günther
Danke für Deinen Tipp - ich werde mich mal mit Power Query beschäftigen.
Dir wünsche ich eine gute Zeit.
Stéphane

304 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige