Textformatierung beim Zusammenfügen von Zellen

Hallo,
ich habe eine Excel-Tabelle1 als Datenliste mit Feld1, Feld2, Feld3.
Im Feld4 will ich die ersten drei Felder zusammenfügen und den Inhalt in einem anderen Tabellenblatt Tabelle 2 einfügen.
Feld4 = Feld1 & Feld2 & Feld3
Ziel ist ein Ausdruck, bei dem die Daten ähnlich wie Etiketten aus einem horizontalen Datensatz in ein Etikett mit untereinander stehenden Daten steht.
Um einen Zeilenumbruch zu erreichen füge ich das Zeichen 10 (Absatz) ein.
Feld4 = Feld1 & ZEICHEN(10) & Feld2 & ZEICHEN(10) & Feld3
Vorteil dieses Verfahrens: Ich habe den gleichen Datensatz aus Tabelle1 Zeile A in der Tabelle 2 Zeile A und kann die Größe der Zelle beim Ausdrucken besser steuern.
Nun meine Frage:
Ich möchte beim Zusammenfügen den Inhalt einige Felder zusätzlich formatieren wie z.B. Schriftgröße, fett etc.
Wünschenswert ist z.B. folgender Algorythmus:
Feld4 = [Schriftgröße(12)] & [Fett] & Feld1 & [Schriftgröße(10)] & [kein Fett] & ZEICHEN(10) & Feld2 & ZEICHEN(10) & Feld3
Hat jemand dafür eine Lösung? Von VBA verstehe ich zu wenig, wobei das wahrscheinlich die beste Lösung sein wird.
Danke für Eure Antwort.

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Stefan,
Texte, die in Excel per Formel zusammengefügt werden kann man nicht zusätzlich speziell formatieren. Dies ist nur möglich, wenn der Zellinhalt Text ist.
Da für die Sonderformatierung des 1. Wortes VBA erforderlich ist, kann man auch das Zusammenfügen der Texte per VBA machen und die Liste auf Blatt 2 komplett per VBA erstellen.
Um den Komfort einwenig zu erhöhen, läßt man das Makro automatisch ablaufen, wenn das Blatt 2 aktiviert wird.
Gruß
Franz
Diese Prozedur im VBA-Editor in einem Modul einfügen, Tabellennamen und Startzeilen für das Auslesen/Eintragen der Daten ggf. anpassen.


Sub LabelText()
'Fügt Inhalte der Spalten A bis C in Tabelle1 in Tabelle 2 _
zeilenweise zusammen und formatiert speziell die Zeichen des 1. Wortes
Dim wks1 As Worksheet, wks2 As Worksheet
Dim Zeile1 As Long, Zeile2 As Long
Set wks1 = Worksheets("Tabelle1")
Set wks2 = Worksheets("Tabelle2")
With wks2.Columns(1)
.ClearContents 'vorhandene Inhalte löschen
.WrapText = True 'Zeilenumbruch in Zellen einstellen
.Font.Size = 10
.Font.Bold = False
End With
With wks1
Zeile2 = 0 'Zeilenzähler Tabelle 2
'Daten aus allen Zeilen mit Daten Spalte A werden ins 2. Blatt übertragen
For Zeile1 = 1 To .Cells(.Rows.Count, 1).End(xlUp).Row
Zeile2 = Zeile2 + 1 'Zeilenzähler erhöhen
'Text in Tabelle 2 einfügen
wks2.Cells(Zeile2, 1) = .Cells(Zeile1, 1) & vbLf & .Cells(Zeile1, 2) & vbLf & .Cells(Zeile1, 3)
'Schriftgröße und Fett für 1.Wort/Zeile einstellen
With wks2.Cells(Zeile2, 1).Characters(1, Len(.Cells(Zeile1, 1)) + 1).Font
.Size = 12
.Bold = True
End With
Next Zeile1
End With
End Sub

Diese Prozedur im VBA-Editor unter der Tabelle einfügen, in der die Inhalte zeilenweise dargestellt werden sollen.


Private Sub Worksheet_Activate()
Call LabelText
End Sub

Beliebteste Forumthreads (12 Monate)

Textformatierung beim Zusammenfügen von Zellen

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Textformatierung beim Zusammenfügen von Zellen

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread