Datum aus TXT Datei importieren

Forumthread: Datum aus TXT Datei importieren

susanne

Hallo , ich habe eine Textdatei mit folgendem Format:
DECIMALSEPARATOR;,
DATESEPARATOR;.
SHORTDATEFORMAT;d.M.yyyy
TIMESEPARATOR;:
TIMEAMSTRING;
TIMEPMSTRING;
LONGTIMEFORMAT;hh:mm:ss
die Daten zeilen sehen so aus:
VAL;3.7.2009 11:52:20;3,00;
Es gelingt mir einfach nicht mit dem
Workbooks.OpenText
die Datumzeile zu importieren,
um daraus eine x/y-Diaframm zu erstellen.
Ich sehe zwar das richtige Format,
und kann es sogar mit:
For Each c In Worksheets(Str2).Range(Puffer)
c.Select
ActiveCell.NumberFormat = "d/m/yyyy h:mm:ss"
umwandeln, aber wenn ich dann eine x-Y Grafik erstellen will,
wird die Datumspalte nicht erkannt,
sondern die Datenpunkte werden einfach nur aufgezählt.
Seltsamerweise erfolgt eine Erkennung, nachdem ich in der Zelle
einen Doppelklick ausgeführt habe.
Multiplizieren mit 1, wie in der Hilfe beschrieben funktioniert nicht.
Kann mir da jemand weiterhelfen?
Hier mal meine Open-funktion:
.....................................
Workbooks.OpenText Filename:=Verzeichnissave & "\" & Dateinamedia _
, Origin:=xlWindows, StartRow:=1, DataType:=xlDelimited, TextQualifier _
:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:= _
True, Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(Array(1, 2) _
, Array(2, 3), Array(3, 1)), DecimalSeparator:=",", _
TrailingMinusNumbers:=False
......................................

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Datum aus TXT Datei importieren

Tino
AW: Datum aus TXT Datei importieren

susanne

AW: Datum aus TXT Datei importieren

13.07.2009 17:44:21

Tino

Hallo,
versuche es mal hiermit.

Option Explicit
'Funktion zum lesen der Textdatei 
Function Lese_TxT(ByVal sFilename As String) As String

Dim F As Integer
Dim sInhalt As String
 ' Existiert die Datei ? 
  If Dir$(sFilename, vbNormal) <> "" Then
    F = FreeFile
    Open sFilename For Binary As #F
    sInhalt = Space$(LOF(F))
    Get #F, , sInhalt
    Close #F
  End If
  
  Lese_TxT = sInhalt
End Function

Sub LeseDatum()
Dim objRegEx As Object, objMatch As Object
Dim strText As String
Dim i As Integer, rngZelle As Range

'Pfad zur Textdatei 
strText = Lese_TxT("C:\Neuer Ordner\TextFile.txt")
'ab welcher Zelle einfügen 
Set rngZelle = Sheets("Tabelle1").Range("A2")

Set objRegEx = CreateObject("VBScript.RegExp")
    With objRegEx
        .MultiLine = True
        .Global = True
        .IgnoreCase = True
        .Pattern = "\d{1,2}.\d{1,2}.\d{4,4} \d{2,2}:\d{2,2}:\d{2,2}" '3.7.2009 11:52:20 
        Set objMatch = .Execute(strText)
    End With
    
    For i = 0 To objMatch.Count - 1
      With rngZelle.Offset(i, 0)
        .Value = CDate(objMatch(i))
        .NumberFormat = "dd/mm/yyyy hh:mm:ss"
      End With
    Next

End Sub

Gruß Tino

AW: Datum aus TXT Datei importieren

14.07.2009 08:48:13

susanne

funktioniert
Danke :-)

Beliebteste Forumthreads (12 Monate)

Forumthread: Datum aus TXT Datei importieren

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread