Herbers Excel/VBA-Archiv
Max und min Wert Finden
- Max und min Wert Finden von Strijbos vom 28.09.2019 17:18:23
- AW: eine flexible Formellösung ... - von neopa C am 28.09.2019 18:02:14
- AW: nachgetragen: ergänzende Erläuterung ... - von neopa C am 28.09.2019 18:10:56
- Bestenliste - von WF am 29.09.2019 19:11:25
Betrifft: Max und min Wert Finden
von: Strijbos
Geschrieben am: 28.09.2019 17:18:23
Hallo zusammen,
Habe eine Tabelle mit Daten
In Spalte B stehen Kalender Wochen
In Spalte C Stehen Zeiten
in Spalte D der Name
Problem ist das Zeiten mehrfach vorkommen können
Ich suche nun eine Formel die mir nun die Max Werte ausgibt
Die Zeit ist so dargestellt SS:MM
Möchte nun die Beste Zeit (Niedrigste Zeit dargestellt bekommen, daneben der Name)
Ist ein 2. mit dem gleichen Wert dann in der Spalte darunter der Nächst.
Das Gleiche dann mit der höchsten Zeit
Kann mir einer Helfen, Ich weis , ich habe noch eine Anfrage gestellt, wo das ein Teil war. Sorry
Danke Gruß Björn
Betrifft: AW: eine flexible Formellösung ...
von: neopa C
Geschrieben am: 28.09.2019 18:02:14
Hallo Börn,
... die es auch ermöglicht, die Datentabelle zu erweitern und auch nachträglich beliebig zu verschieben könnte z.B. so definiert werden, wie nachfolgende aufgeziegt. Formeln E3; F2, H3 und I2 einfach nach unten kopieren.
| Arbeitsblatt mit dem Namen 'Tabelle1' | |||||||||
| A | B | C | D | E | F | G | H | I | |
| 1 | Woche | Zeit | Name | BestZeit | Name | Max Zeit | Name | ||
| 2 | KW_25 | 02:25 | Name 1 | 02:09 | Name 3 | 02:33 | Name 2 | ||
| 3 | KW_25 | 02:33 | Name 2 | 02:09 | Name 5 | 02:33 | Name 6 | ||
| 4 | KW_25 | 02:09 | Name 3 | 02:09 | Name 8 | ||||
| 5 | KW_25 | 02:22 | Name 4 | ||||||
| 6 | KW_25 | 02:09 | Name 5 | ||||||
| 7 | KW_25 | 02:33 | Name 6 | ||||||
| 8 | KW_25 | 02:15 | Name 7 | ||||||
| 9 | KW_25 | 02:09 | Name 8 | ||||||
| 10 | KW_25 | 02:22 | Name 9 | ||||||
| 11 | |||||||||
| Zelle | Formel |
| E2 | =MIN(_DatTab[Zeit]) |
| F2 | =WENN(E2="";"";INDEX(_DatTab[Name];AGGREGAT(15;6;ZEILE(_DatTab)/(_DatTab[Zeit]=E2);ZÄHLENWENN(E$2:E2;E2))-ZEILE(_DatTab)+1)) |
| H2 | =MAX(_DatTab[Zeit]) |
| I2 | =WENN(H2="";"";INDEX(_DatTab[Name];AGGREGAT(15;6;ZEILE(_DatTab)/(_DatTab[Zeit]=H2);ZÄHLENWENN(H$2:H2;H2))-ZEILE(_DatTab)+1)) |
| E3 | =WENN(KKLEINSTE(_DatTab[Zeit];ANZAHL(E$2:E2)+1)=E2;E2;"") |
| H3 | =WENN(KGRÖSSTE(_DatTab[Zeit];ANZAHL(H$2:H2)+1)=H2;H2;"") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Gruß Werner
.. , - ...
Betrifft: AW: nachgetragen: ergänzende Erläuterung ...
von: neopa C
Geschrieben am: 28.09.2019 18:10:56
Hallo,
... für die "Quelldaten" (in meinem Beispiel A1:C10) hab ich mit der Funktion "Als Tabelle formatieren" angewendet. Den dadurch dieser automatisch zugewiesene Bereichsname: "Tabelle1" hab ich im Namensmanager in "_DatTab" umbenannt, um eine eindeutige Unterscheidung zum Tabellenblattnamen herzustellen.
Gruß Werner
.. , - ...
Betrifft: Bestenliste
von: WF
Geschrieben am: 29.09.2019 19:11:25
Hi,
die Zeiten stehen ab C2 und die Namen ab D2 runter.
In E1 steht die Bestzeit:
=MIN(C1:C99)
In E2 steht die Arrayformel:
{=WENNFEHLER(INDEX(D:D;KKLEINSTE(WENN(C$1:C$99=E$1;ZEILE(X$1:X$99));ZEILE(X1)));"")}
runterkopieren
WF