Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Makro funktioniert nicht mehr

Makro funktioniert nicht mehr
Wolfgang
Hallo,
obwohl ich leider keine Ahnung von VBA habe; Perl ist mir da lieber; konnte ich mir trotzdem vor längerer Zeit mit Hilfe verschiedenen Foren eine Makro zusammen bauen.
Dieses Makro macht folgendes unter Excel 2003.
In die erste Spalte "A" werden manuell Artikelnummern eingebeben.
Dann wird das Makro ausgeführt und dann werden in die 3. Spalte "C" Bilder aus einem Verzeichnis eingefügt.
Die Bilder werden auch gleichzeitig auf eine Größe gebracht.
Der Namen der Bilder entspricht den Artikelnummern in der 1. Spalte.
Also Spalte A-> Artikelnummer 1255 -> Bild 1255.jpg in Spalte C ablegen und dabei vorher auf die eingestellte Größe bringen.
Das funktionierte unter Excel 2003 super, aber unter Excel 2007 funktioniert es so, das alle Bilder übereinander in der ersten Zelle abgelegt werden, anstatt sie den einzelnen Zellen zuzuordnen.
[Code]

Sub Bilder_einfügen()
Dim PhotoWidth As Integer
Dim PhotoHeight As Integer
Dim Pfad As String
Dim Wiederholungen As Long
PhotoWidth = 50.25
PhotoHeight = 30.75
On Error Resume Next
Pfad = "C:\Bilder\"
For Wiederholungen = 2 To Range("A65536").End(xlUp).Row
Cells(Wiederholungen, 3).Activate
ActiveSheet.Pictures.Insert(Pfad & Cells(Wiederholungen, 1) & ".jpg").Select
Selection.ShapeRange.Height = PhotoHeight
Selection.ShapeRange.Width = PhotoWidth
Next
End Sub

[/Code]
Ich habe bis jetzt rausgefunden, das die Zeile
[Code]
Cells(Wiederholungen, 3).Activate
[/Code]
nicht funktioniert.
Was ist falsch?
Für schnelle Hilfe wäre ich dankbar.

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Makro funktioniert nicht mehr
14.10.2009 20:56:20
Josef
Hallo Wolfgang,
ohne Select und Activate und so läuft's auch unter xl2007.
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub Bilder_einfügen()
  
  Dim PhotoWidth As Double, PhotoHeight As Double
  Dim Pfad As String
  Dim Wiederholungen As Long
  Dim objShp As Object
  
  PhotoWidth = 50.25
  PhotoHeight = 30.75
  
  
  Pfad = "C:\Bilder\"
  For Wiederholungen = 2 To Cells(Rows.Count, 1).End(xlUp).Row
    If Dir(Pfad & Cells(Wiederholungen, 1).Text & ".jpg") <> "" Then
      Set objShp = ActiveSheet.Pictures.Insert(Pfad & Cells(Wiederholungen, 1).Text & ".jpg")
      With objShp
        .Height = PhotoHeight
        .Width = PhotoWidth
        .Top = Cells(Wiederholungen, 3).Top
        .Left = Cells(Wiederholungen, 3).Left
      End With
    End If
  Next
  
  Set objShp = Nothing
End Sub

Gruß Sepp

Anzeige
AW: Makro funktioniert nicht mehr
16.10.2009 20:44:51
Wolfgang
Hallo,
wow!
Ich kann mich nur ganz herzlich für diese super schnelle, tolle und funktionierende Antwort bedanken!
Toller Support und tolles Forum!
Bis denn
Wolfgang

334 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige