Werte per VBA in andere Tabelle kopieren

Liebe Herber-Forum-Gemeinde,
ich wäre euch sehr dankbar, wenn ihr mir (VBA-Newbie) mit folgendem VBA-Code/Problem helfen könntet.
Das Forum habe ich bereits durchsucht, leider habe ich (noch) nicht die passende Antwort für dieses spezifische Problem gefunden.
Ich möchte monatlich Werte (ganze Zahlen) von einem vorgefertigten Tabellenblatt in eine fortlaufende Planung (separates Tabellenblatt) per Makro übertragen. Das Makro soll sozusagen anhand zweier Kriterien in Tabellenblatt B (bspw. Kennzahl (Zeile) & Monat (Spalte) die richtige Zelle in Tabellenblatt A suchen und den in Tabellenblatt B hinterlegten Wert für diese Kombi in diese Zelle (per Knopfdruck) kopieren.
Eine Formellösung, welche einfach wäre, scheidet aus diversen Gründen aus.
In angehängter Datei habe ich die Problemstellung in vereinfachter Form hinterlegt:
https://www.herber.de/bbs/user/142374.xlsx
Für eure Hilfe bedanke ich mich recht herzlich im Voraus.
Viele Grüße
Thomas

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Thomas,
teste mal:

Option Explicit

Public Sub CopyValues()

    Dim avntValues As Variant
    Dim strMonth As String
    Dim lngMonthColumn As Long, ialngIndex As Long
    Dim objCell As Range

    strMonth = Trim$(Worksheets("Quelle - IST-Zahlen").Cells(1, 2).Text)

    If strMonth <> vbNullString Then

        With Worksheets("Zieltabelle")

            Set objCell = .Rows(3).Find(What:=strMonth, LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)

            If objCell Is Nothing Then
                Call MsgBox("Monat nicht gefunden.", vbCritical, "Programmabbruch")
                Exit Sub
            Else
                lngMonthColumn = objCell.Column
                Set objCell = Nothing
            End If

            avntValues = .Range(.Cells(4, 2), .Cells(.Rows.Count, 2).End(xlUp)).Value2

        End With

        With Worksheets("Quelle - IST-Zahlen")

            For ialngIndex = LBound(avntValues, 1) To UBound(avntValues, 1)

                Set objCell = .Range(.Cells(4, 2), .Cells(.Rows.Count, 2)).Find( _
                    What:=avntValues(ialngIndex, 1), LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)

                If Not objCell Is Nothing Then _
                    Worksheets("Zieltabelle").Cells(ialngIndex + 3, lngMonthColumn).Value = objCell.Offset(0, 1).Value

            Next

            Set objCell = Nothing

        End With
    Else
        Call MsgBox("Kein Monat ausgewählt.", vbCritical, "Programmabbruch")
    End If
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

Werte per VBA in andere Tabelle kopieren

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

317 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Werte per VBA in andere Tabelle kopieren

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

317 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread