Mit Tab aus Zelle in Textfeld



Excel-Version: Versionsunabhängig
nach unten

Betrifft: Mit Tab aus Zelle in Textfeld
von: Marcus
Geschrieben am: 02.07.2002 - 09:41:34

Hallo,

ist es möglich aus einer Zelle mittels der Tab-Taste in ein Textfeld zu springen (und ggf. von dort aus auch weiter in die nächste Zelle)?
Wenn ja, wie mach ich das? (In meiner Excel-Datei sollen nur 2 Zellen + besagtes Textfeld bearbeitet werden können.)

Vorab vielen Dank!
Gruß, Marcus


nach oben   nach unten

Re: Mit Tab aus Zelle in Textfeld
von: Andreas
Geschrieben am: 02.07.2002 - 10:02:05

Hallo Marcus,

wenn Du in der Datei wirklich nur 2 Felder und das Textfeld benutzen willst, dann wäre das hier eine Möglichkeit:


'*** Code in DieseArbeitsmappe: ***
Private Sub Workbook_Activate()
    Application.OnKey "{TAB}", "SwitchRange"
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Application.OnKey "{TAB}"
End Sub

Private Sub Workbook_Deactivate()
    Application.OnKey "{TAB}"
End Sub

Private Sub Workbook_Open()
    Application.OnKey "{TAB}", "SwitchRange"
End Sub

'*** Code in einem Modul: ***
Sub SwitchRange()
On Error GoTo ErrorHandler
Select Case Selection.Address(False, False)
    Case "A1": ActiveSheet.Shapes("Text Box 1").Select
    Case "B1": Range("A1").Select
End Select

Exit Sub
ErrorHandler:
    Range("B1").Select
End Sub

Also beim Drücken der Tabulator-Taste wird jeweils das Makro SwitchRange aufgerufen. Dieses wechselt dann je nach Ausgangspunkt, also von A1 ins Textfeld, vom Textfeld in die Zelle B1 und von B1 wieder zur Zelle A1.
Mußt nun nur noch die Zelle anpassen und die richtige Bezeichnung von Deinem Textfeld im Makro angeben!

Ich habe noch einige zusätzliche Ereignisse definiert, damit Du beim wechseln in andere Dateien, die ursprüngliche Bedeutung von TAB wieder hast!

Viel Spaß,
Andreas

nach oben   nach unten

Re: Mit Tab aus Zelle in Textfeld
von: Marcus
Geschrieben am: 02.07.2002 - 10:10:10

Super, danke Dir!

Gruß,
Marcus


 nach oben

Beiträge aus den Excel-Beispielen zum Thema "Mit Tab aus Zelle in Textfeld"