Wenn-Dann Bdingung Teil 2

Bild

Betrifft: Wenn-Dann Bdingung Teil 2 von: Mikel
Geschrieben am: 08.04.2005 18:52:44

Hallo nochmal,
ich glaube ich habe mich gestern nicht richtig ausgedrückt,deswegen habe ich die tabelle mit gepostet.
Problem: Von der Arbeitszeit sollen bis 6 Arbeitsstunden keine Pause, über 6 Stunden 30 Minuten und über 9 Stunden 45 Minuten abgezogen werden.
Ich habe es bisher mit der Wenn-Dann Bedingung versucht.
Frage: Warum nimmt er nur die erste Dann Bedingung an?

Der Vorschlag von Ransi funktioniert nicht, weil nur eine Zelle pro Zeile für die Pausen gelten soll.

Vieleicht kann mir ja jemand helfen?

Gruß Mikel


Arbeitszeitzettel
 ABCD
1AnAbPauseArbst.o.Pause
212:0016:00 04:00
312:0018:300:3006:00
412:0021:000:3008:30
Formeln der Tabelle
D2 : =B2-A2
C3 : =WENN(B3-A3>0,25;"0:30";WENN(B3-A3>0,375;"0:45";""))
D3 : =B3-A3-C3
C4 : =WENN(B4-A4>0,25;"0:30";WENN(B4-A4>0,375;"0:45";""))
D4 : =(B4-A4-C4)
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  

Bild


Betrifft: erst die größere bedingung abfragen. von: ransi
Geschrieben am: 08.04.2005 19:21:34

hallo mikel

ich habe versucht dir zu erklären das du erst auf den größeren wert abfragen musst.
in deinem beispiel fragst du erst die kleinere ab.
 
 ABCD
1AnAbPauseArbst.o.Pause
212:0016:0000:0004:00
312:0018:3000:3006:00
412:0021:0100:4508:16
Formeln der Tabelle
C2 : =WENN((B2-A2)>0,375;"0:45";WENN((B2-A2)>0,25;"0:30"))*1
D2 : =B2-A2-(C2*1)
C3 : =WENN((B3-A3)>0,375;"0:45";WENN((B3-A3)>0,25;"0:30"))*1
D3 : =B3-A3-(C3*1)
C4 : =WENN((B4-A4)>0,375;"0:45";WENN((B4-A4)>0,25;"0:30"))*1
D4 : =B4-A4-(C4*1)
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  

lass dich durch das *1 in der spalte c nicht irritieren.
ist notwendig damit dort kein falsch steht wenn die differenz < 6 ist.

bei der wenn() funktion ist das nunmal so:
wenn die wenn bedingungung erfüllt ist, gibt es kein sonst.

ransi


Bild


Betrifft: AW: Wenn-Dann Bdingung Teil 2 von: HermannZ
Geschrieben am: 08.04.2005 19:26:52

Hallo Mikel,
das liegt daran das deine erste Wenn bedingung in deinem Beispiel immer wahr ergibt,
und wenn bei einer WENN Funktion die erste Bedingung Wahr ergibt wird jede weitere Bedingung
nicht mehr beachtet.

=WENN(B3-A3>0,375;"0:45";WENN(B3-A3>0,25:"0:30";""))

Gruß hermann


Bild


Betrifft: seeehr gut erklärt. o.T. von: ransi
Geschrieben am: 08.04.2005 19:31:14




Bild


Betrifft: Wenn schon denn schon von: serge
Geschrieben am: 08.04.2005 19:57:52

Wenn schon denn schon, fürs Auge in der Tabelle
=WENN(B2-A2>0.375;0.03125;WENN(B2-A2>0.25;0.0208333333333333;0))
Serge


Bild


Betrifft: AW: Wenn-Dann Bdingung Teil 2 von: serge
Geschrieben am: 08.04.2005 19:42:34

Hi Mikel
ich habe es so gelöst:
https://www.herber.de/bbs/user/20894.xls
Serge


Bild


Betrifft: AW: Wenn-Dann Bdingung Teil 2 von: Mikel
Geschrieben am: 08.04.2005 19:52:59

Hi serge,
Auch nett, dann muss man nicht umständlich die Zeit in Dezimalzahlen umrechnen.
Klasse Tip!


Bild


Betrifft: AW: Wenn-Dann Bdingung Teil 2 von: Mikel
Geschrieben am: 08.04.2005 19:45:33

Hallo an Beide,
Danke,Danke,Danke!
Hier werdet ihr echt geholfen!
P.S.: Ist die erste Bedingung immer wahr, wenn sie kleiner als die zweite ist?


Bild


Betrifft: AW: zu deiner Frage....... von: HermannZ
Geschrieben am: 08.04.2005 20:24:39

Hallo Mikel,

ich hoffe das hilft dir die Funktion zu verstehen.

Beispiel;

Text
 ABCDE
937     
938AnAbPauseArbst.o.Pause 
93912:0016:0000:00:0004:00 
94012:0018:3000:30:0006:00 
94112:0021:0100:45:0008:16 
942     
943Erläuterung für    
944Formel in C939 =WENN((B939-A939)>0,375;"0:45";WENN((B939-A939)>0,25;"0:30"))*1
945     
946 Der Teil der Formel; WENN((B939-A939)>0,375 
947 ergibt in diesem Beispiel FALSCH
948 weil B939-A939 <0,375 ist
949 somit wird der zweite Teil; WENN((B939-A939)>0,25;
950 abgefragt und dieser ergibt wieder FALSCH
951 weil auch B939-A939<0,25 ist
952 und somit wird der zellwert auf NULL gesetzt was bei dieser
953 Formatierung als Zeitwert 00:00:00 dargestellt wird
954Erläuterung für    
955Formel in C940 =WENN((B939-A939)>0,375;"0:45";WENN((B939-A939)>0,25;"0:30"))*1
956     
957 Der Teil der Formel; WENN((B939-A939)>0,375
958 ergibt in diesem Beispiel FALSCH
959 weil B939-A939 <0,375 ist
960 somit wird der zweite Teil; WENN((B939-A939)>0,25;
961 abgefragt und dieser ergibt WAHR
962 weil B939-A939>0,25 ist
963 und somit wird der DANN Wert ausgegeben
964 was in diesem Beispiel der Wert 0:30 ist
965Erläuterung für    
966Formel in C941 =WENN((B939-A939)>0,375;"0:45";WENN((B939-A939)>0,25;"0:30"))*1
967     
968 Der Teil der Formel; WENN((B939-A939)>0,375
969 ergibt in diesem Beispiel WAHR
970 weil B939-A939 >0,375 ist
971 und somit wird der DANN Wert ausgegeben
972 was in diesem Beispiel der Wert 0:45 ist
973 die weitere Bedingung der Formel wird
974 ignoriert
975     
976 Der Wert am Ende der Formel *1 muß bei dieser Formel
977 so gesetzt werden weil sonst bei keiner Übereinstimmung
978 der Wert FALSCH ausgegeben wird.
979     
980 Ich hoffe dir hilft diese Erklärung!   
981     
Formeln der Tabelle
C939 : =WENN((B939-A939)>0,375;"0:45";WENN((B939-A939)>0,25;"0:30"))*1
C940 : =WENN((B940-A940)>0,375;"0:45";WENN((B940-A940)>0,25;"0:30"))*1
C941 : =WENN((B941-A941)>0,375;"0:45";WENN((B941-A941)>0,25;"0:30"))*1
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  


Gruß hermann


Bild


Betrifft: Danke für deine Antwort von: Mikel
Geschrieben am: 09.04.2005 13:56:35

Hallo Hermann,

Supeeeeeeeeeer erklärt! Vielen Dank für deine Mühe.
Jetzt habe ich endlich genaustens verstanden in welcher Beziehung die Begriffe "Wenn", "Dann" und "Sonst" in der Wenn-Bedingung zu einander stehen.

Gruß
Mikel


 Bild

Beiträge aus den Excel-Beispielen zum Thema "Timeout eines Makros abfangen"