Dateien zusammenführen, Dateiname mit übernehmen

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
MsgBox
Bild

Betrifft: Dateien zusammenführen, Dateiname mit übernehmen von: Robert
Geschrieben am: 23.02.2005 08:56:27

Hallo,

heute melde ich mich auch mal wegen einem Problem,

Ich möchte den Inhalt einiger hundert .dat files in ein Excel-File untereinander kopieren. Diese befinden sich alle in einem Ordner. ich benutze dazu folgenden code:


Sub DATFILESHOLEN()
Application.DisplayAlerts = False
Dim i, zaehler1, zaehler2, zaehler3, a, b, alta, altb, lzeile, lspalte
Dim lastcell As Range
With Application.FileSearch
.NewSearch
.LookIn = "G:\Files"
.SearchSubFolders = False
.Filename = "*.dat"
If .Execute() > 0 Then
For i = 1 To .FoundFiles.Count
Workbooks.Open Filename:=.FoundFiles(i)
Set lastcell = ActiveSheet.Cells.SpecialCells(xlLastCell)
alta = lastcell.Row
a = lastcell.Row
Do While Application.CountA(Rows(a)) = 0 And a <> 1
a = a - 1
Loop
alta = a
altb = lastcell.Column
b = lastcell.Column
Do While Application.CountA(Columns(b)) = 0 And b <> 1
b = b - 1
Loop
altb = b
lzeile = alta
lspalte = altb
For zaehler2 = 1 To lzeile
zaehler1 = zaehler1 + 1
For zaehler3 = 1 To lspalte
Workbooks(1).Sheets(1).Cells(zaehler1, zaehler3) = Workbooks(2).Sheets(1).Cells(zaehler2, zaehler3)
Next zaehler3
Next zaehler2
Workbooks(2).Close
Next i
End If
End With
Application.DisplayAlerts = True
End Sub


Wie muss ich den Code ändern, damit die Daten in Spalte B eingefügt und der Dateiname des Ursprungs-.dat-files in jeder Zeile vor dem eingefügten Inhalt stehen?

vielen Dank für Eure Tips!

Gruss
Robert
Bild


Betrifft: AW: Dateien zusammenführen, Dateiname mit übernehmen von: Nike
Geschrieben am: 23.02.2005 10:09:31

Hi,
versuchs mal so:


Sub Dat_Import()
'By Nike 23.02.2005
Dim wkb As Workbook
Dim wksZiel As Worksheet
Dim wkbQuell As Workbook
Dim wksQuell As Worksheet
Dim lngQSpalt As Long
Dim lngQZeil As Long
Dim lngZZeil As Long
Dim varArr As Variant
Dim i As Integer
Dim strNam As String
Set wkb = ActiveWorkbook
Set wksZiel = wkb.Worksheets(1)
Selection:
   ' Zu öffnende Dateien erfragen
    arrFilenames = Application.GetOpenFilename( _
        "Dat Dateien (*.dat), *.dat", 1, _
        "Dat Dateien auswählen...", MultiSelect:=True)                ' Ausgewählte Datei des Öffnen-Dialoges in Feld ablegen
    If VarType(arrFilenames) = vbBoolean Then
        If MsgBox("Sie haben keine Dateien ausgewählt. Möchten sie das Makro beenden?", vbYesNo, "Frage") = vbNo Then
            GoTo Selection
        Else
            Exit Sub
        End If
    End If
    
'Application.ScreenUpdating = False
   ' Die vom Makro vorgenommenen Tätigkeiten
   ' bleiben zur Geschwidigkeitssteigerung unsichtbar
    
For i = 1 To UBound(arrFilenames)
'-------------------------------------------------------
'hier kommt dann der Code rein, der die geoeffneten Dateien betrifft
'betrifft. Die Ursprungsdatei ist über wksZiel ansprechbar.
'das Quell Blatt ist wksQuell
lngZZeil = wksZiel.Cells(wksZiel.Rows.Count, 1).End(xlUp).Row
If lngZZeil > 1 Then
    lngZZeil = lngZZeil + 1
End If
Workbooks.Open (arrFilenames(i))
    
Set wkbQuell = ActiveWorkbook
Set wksQuell = ActiveSheet
'wksQuell.Copy after:=wkb.Worksheets(wkb.Worksheets.Count)
lngQZeil = wksQuell.Cells(wksQuell.Rows.Count, 1).End(xlUp).Row
lngQSpalt = wksQuell.Cells(1, wksQuell.Columns.Count).End(xlToLeft).Column
'wksZiel.Range(wksZiel.Cells(lngZZeil, 2), wksZiel.Cells(lngZZeil, lngQSpalt).Offset(lngQZeil - 1, 1)).Select
'wksQuell.Range(wksQuell.Cells(1, 1), wksQuell.Cells(lngQZeil, lngQSpalt)).Select
wksQuell.Range(wksQuell.Cells(1, 1), wksQuell.Cells(lngQZeil, lngQSpalt)).Copy _
wksZiel.Range(wksZiel.Cells(lngZZeil, 2), wksZiel.Cells(lngZZeil, lngQSpalt).Offset(lngQZeil - 1, 1))
'wksZiel.Range(wksZiel.Cells(lngZZeil, 2), wksZiel.Cells(lngZZeil, 2).Offset(lngQZeil + 1, lngQSpalt + 1))
wksZiel.Range(wksZiel.Cells(lngZZeil, 1), wksZiel.Cells(lngZZeil + lngQZeil - 1, 1)).Value = wkbQuell.Name
wkbQuell.Close (False)
Next
'-------------------------------------------------------
    wkb.Save
    'Ursprüngliche Datei wieder aktivieren
    'wkb.Activate
    Application.ScreenUpdating = True
    'und den Monitor aktivieren
End Sub




Function FileOpenYet(FileName As String) As Boolean
'eine Funktion, die Prüft ob eine Datei schon geöffnet ist.
Dim s As String
On Error GoTo Nonexistent
s = Workbooks(FileName).Name
FileOpenYet = True
Exit Function
Nonexistent:
FileOpenYet = False
End Function


Bye

Nike


 Bild

Beiträge aus den Excel-Beispielen zum Thema "Dateien zusammenführen, Dateiname mit übernehmen"