Suchen in Text+Zahl

Forumthread: Suchen in Text+Zahl

Suchen in Text+Zahl

12.05.2006 14:44:36

henrik

hallo zusammen,
habe folgendes Problem. möchte aus Tabellenblatt(1) eine summe bekommen, die mir in Tabellenblatt(2) angezeigt wird, wenn 2 kriterien aus tabellenblatt(2) erfüllt sind. noch klingt es einfach.
Also:
Tabellenblatt(2)
Zelle(C3)= Kriterium1 (Ein- bzw. Zweistellige Zahl) z.B. 15
Zelle(C4)= Kriterium2 (Text) z.B. groß
Zelle(C5)= Ergebnis (Zahl) MÖCHTE ICH GERNE BEKOMMEN
Tabellenblatt(1)
Zellen(C10:C20)= Suchbereich1 (Zahl oder Zahl+Text) z.B. 15001 oder 1500F
Zellen(D10:D20)= Suchbereich2 (Text) z.B. Großraum
Zellen(F10:F20)= Werte (Zahl)
Hab es so versucht:
Formel steht in Zelle(C5) in Tabellenblatt(2)
{=SUMME((LINKS('Tabelle1'!D10:D20;LÄNGE(C4))=C4)*(LINKS(FEST('Tabelle1'!C10:C20;0;WAHR);2)=FEST(C3;0;WAHR))*('Tabelle1'!F10:F20))}
funktioniert auch, solange im Suchbereich1 keine Zahl+Text auftaucht z.B. 1500F.
Weiß jemand Rat?
gruß henrik

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Suchen in Text+Zahl

12.05.2006 15:13:21

Franz
Funktioniert

12.05.2006 15:32:44

henrik
Wozu eigentlich FEST() ?

12.05.2006 15:52:02

{Boris}
Danke Boris aber Frage

12.05.2006 16:26:15

henrik
Zahl zu Text machen

14.05.2006 00:04:49

{Boris}

AW: Suchen in Text+Zahl

12.05.2006 15:13:21

Franz

Hallo Hendrik,
probiere mal folgende Variante als Matrixformel:
{=SUMME((LINKS(Tabelle1!D10:D20;LÄNGE(C4))=C4)*(WENN(ISTTEXT(Tabelle1!C10:C20); LINKS(Tabelle1!C10:C20;2);LINKS(FEST(Tabelle1!C10:C20;0;WAHR);2))= FEST(C3;0;WAHR))*(Tabelle1!F10:F20))}
Gruß
Franz

Funktioniert

12.05.2006 15:32:44

henrik

hallo Franz,
funktioniert bestens. herzlichen Dank
Gruß henrik

Wozu eigentlich FEST() ?

12.05.2006 15:52:02

{Boris}

Hi Henrik,
ohne geht´s noch etwas einfacher mit:
{=SUMME((LINKS(Tabelle1!C10:C20;LÄNGE(C3))=C3&"")*(LINKS(Tabelle1!D10:D20;LÄNGE(C4))=C4)*Tabelle1!F10:F20)}
oder nicht als Arrayformel mit
=SUMMENPRODUKT((LINKS(Tabelle1!C10:C20;LÄNGE(C3))=C3&"")*(LINKS(Tabelle1!D10:D20;LÄNGE(C4))=C4)*Tabelle1!F10:F20)
Grüße Boris

Danke Boris aber Frage

12.05.2006 16:26:15

henrik

hallo Boris,
funktioniert auch beides. Danke Dir.
habe aber noch eine Frage.
was bewirkt denn der Ausdruck &"" in ...links(...)=C3&"")*(.... ?
ohne den funktioniert es ja nicht.
gruß
henrik

Zahl zu Text machen

14.05.2006 00:04:49

{Boris}

Hi Henrik,
in C3 hast du ja eine Zahl stehen (z.B. die 15). Den Suchbereich (Tabelle1!C10:C20) durchsuchen wir aber mit der Funktion LINKS() - und diese gibt als Ergebnis immer TEXT zurück. Wenn man jetzt Text mit Zahl vergleicht, wird das Ergebnis niemals identisch sein. Also entweder beides zu Zahlen machen (das geht aber nicht so ohne Weiteres) oder eben BEIDES zu Text. Und wenn du eine Zahl mit einem Leerstring verkettest, dann machst du eben Text draus.
Grüße Boris

Beliebteste Forumthreads (12 Monate)

Forumthread: Suchen in Text+Zahl

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread