Textboxeintrag in Spalte A suchen

Forumthread: Textboxeintrag in Spalte A suchen

09.05.2006 20:23:43

harald

Hallo,
ich habe noch mal ein Problem: In meiner Tabelle stehen in Spalte A ab Zeile 4 Namen, die alphabet. sortiert sind. In Zeile 2 ist eine Textbox. Nun möchte ich erreichen, dass bei Eingabe eines Namens automatisch die entsprechende Zelle markiert wird - wenn möglich sogar schon bei Eingabe der ersten Buchstaben (z. B bei Eingabe von M soll der erste Name mit M markiert werden, wenn danach ein ü eingegeben wird, soll das erste Mü erscheinen u.s.w.)
Ist das machbar?
m.f.g.
harald

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Textboxeintrag in Spalte A suchen

09.05.2006 21:19:06

Peter

Hallo Harald,
das nachfolgende Makro gehört in das Tabellenblatt mit deiner TextBox und den Daten


Private Sub TextBox1_Change()
Dim lLetzte   As Long
Dim Zelle     As Range
Dim firstAdr  As String
Dim Nachname  As String
Nachname = ActiveSheet.TextBox1
lLetzte = ActiveSheet.Cells(Rows.Count, 1).End(xlUp).Row
With ActiveSheet.Range("A4:A" & lLetzte)
Set Zelle = .Find(Nachname, LookIn:=xlValues, lookat:=xlPart)
If Not Zelle Is Nothing Then
firstAdr = Zelle.Address
Do
Zelle.Select
Set Zelle = .FindNext(Zelle)
Loop While Not Zelle Is Nothing And Zelle.Address <> firstAdr
Else
MsgBox "Der Name " & Nachname & _
" wurde nicht gefunden.", _
16, "   Den gesuchten Namen gibt es nicht."
End If
End With
End Sub

Viele Grüße Peter
Eine kurze Nachricht, ob es läuft, wäre nett - danke.

AW: Textboxeintrag in Spalte A suchen

10.05.2006 06:48:38

harald

Hallo Peter,
leider wird bei deiner Version nicht die korrekte Zelle markiert. Ich habe die Datei einmal hochgeladen:
https://www.herber.de/bbs/user/33491.xls
Die Version von Franz funktioniert aber. Trotzdem vielen Dank für deine Mühe!
m.f.g.
harald

AW: Textboxeintrag in Spalte A suchen

09.05.2006 22:09:51

Franz

Hallo Harald,
Hier meine Alternative. Sie markiert während der Eingabe die Zelle gelb und scrolled den Bildschirm. Dazu sollte das Fenster unterhalb der 3. Zeile fixiert werden! Beim Verlassen der Textbox wird die Zelle mit dem zuletzt gefundenen Befriff selektiert.


Private Sub TextBox1_Change()
'Markiert die Zelle, die mit dem gesuchten Begriff beginnt
Dim Zelle As Range, Bereich As Range
With ActiveSheet
Set Bereich = .Range("A4:A" & .UsedRange.Row + .UsedRange.Rows.Count - 1)
End With
If TextBox1.Value = "" Then
Range("A4").Activate
Bereich.Interior.ColorIndex = xlColorIndexNone
ActiveWindow.ScrollRow = 4
TextBox1.Activate
Exit Sub
End If
For Each Zelle In Bereich
If Left(Zelle.Value, Len(TextBox1.Value)) = TextBox1.Value Then
Zelle.Activate
Bereich.Interior.ColorIndex = xlColorIndexNone
Zelle.Interior.ColorIndex = 6
ActiveWindow.ScrollRow = Zelle.Row
TextBox1.Activate
Exit For
End If
Next Zelle
End Sub
Private Sub TextBox1_LostFocus()
'Beim Verlassen wird die Zelle mit dem gesuchten Text selektiert und Farbmarkierung zurückgesetzt
Dim Zelle As Range, Bereich As Range
With ActiveSheet
Set Bereich = .Range("A4:A" & .UsedRange.Row + .UsedRange.Rows.Count - 1)
End With
If TextBox1.Value = "" Then
Bereich.Interior.ColorIndex = xlColorIndexNone
ActiveSheet.Range("A4").Select
Exit Sub
End If
For Each Zelle In Bereich
If Left(Zelle.Value, Len(TextBox1.Value)) = TextBox1.Value Then
Zelle.Interior.ColorIndex = xlColorIndexNone
Zelle.Select
Exit For
End If
Next Zelle
End Sub

Gruß
Franz

AW: Textboxeintrag in Spalte A suchen

10.05.2006 06:50:05

harald

Hallo Franz,
vielen Dank für deine Mühe - das Programm funktioniert wie ich es mir vorgestellt habe!
m.f.g.
harald

Beliebteste Forumthreads (12 Monate)

Textboxeintrag in Spalte A suchen

Forumthread: Textboxeintrag in Spalte A suchen

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Textboxeintrag in Spalte A suchen

Forumthread: Textboxeintrag in Spalte A suchen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread