Teile einer Zelle in eine neue Zelle schreiben
Betrifft: Teile einer Zelle in eine neue Zelle schreiben
von: {mskro}
Geschrieben am: 05.08.2015 10:46:33
Hallo Excelfreunde,
ich habe wieder mal ein kleines Problem und benötige Hilfestellung.
Ich muß aus einer Zelle 3 Zahlen (keinen Text), die jeweils dur einen Schrägstrich getrennt sind herausholen und in eine andere Zelle Schreiben. Die Zahlen können 1- oder 2-stellig sein. Da komme ich mit der mir bekannten Formel ala "LINKS(B11;FINDEN("/";B11)-1" oder auch"RECHTS(...)" nicht wirklich weiter, da der Schrägstrich ja nicht nur einmal darin enthalten ist.
Hat hier jemand eine Lösung für mich?
Mögliche Zelleninhalt:
Lager1/2/1
Standortname10/8/12
Name5/10/40
Ergebnisse sollen sein:
1/0/1
10/8/12
5/10/40
-leer-, wenn kein / in der Zelle vorhanden ist.
Vielleicht sogar in einzelne Zellen geschrieben. Das wird sich aber erst später zeigen, was für die Weiterverabeitung dann besser sein wird.
Gruß Manfred
|
Betrifft: wenn die /-Zahlen immer am Schluss stehen
von: WF
Geschrieben am: 05.08.2015 11:00:03
Hi,
folgende Arrayformel:
{=TEIL(A1;VERGLEICH(WAHR;ISTZAHL(TEIL(A1;ZEILE(1:99);1)*1);0);99)}
Salut WF
Betrifft: besser -> ZEILE($1:$99) ? kwT
von: Matthias L
Geschrieben am: 05.08.2015 11:08:56
Betrifft: Du meintest -> ZEILE(A1:A99)
von: WF
Geschrieben am: 05.08.2015 11:13:22
.
Betrifft: verdammt -> ZEILE(A$1:A$99)
von: WF
Geschrieben am: 05.08.2015 11:16:05
.
Betrifft: AW: Du meintest -> ZEILE(A1:A99)
von: Matthias L
Geschrieben am: 05.08.2015 11:19:20
Hallo WF
Hab ichs falsch verstanden ?
Wenn ich in B1 Deine Formel eingebe und runterkopiere ändert sich ja der Zeilen-Bezug, oder?
| | A | B |
| 1 | Lager1/2/1 | 1/2/1 |
| 2 | Standortname10/8/12 | e10/8/12 |
| 3 | Name5/10/40 | me5/10/40 |
| Formeln der Tabelle |
| Zelle | Formel | | B1 | {=TEIL(A1;VERGLEICH(WAHR;ISTZAHL(TEIL(A1;ZEILE(1:99);1)*1);0);99)} | | B2 | {=TEIL(A2;VERGLEICH(WAHR;ISTZAHL(TEIL(A2;ZEILE(2:100);1)*1);0);99)} | | B3 | {=TEIL(A3;VERGLEICH(WAHR;ISTZAHL(TEIL(A3;ZEILE(3:101);1)*1);0);99)} |
|
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen! |
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Deshalb dachte ich, ich machs mal Absolut
| | A | B |
| 1 | Lager1/2/1 | 1/2/1 |
| 2 | Standortname10/8/12 | 10/8/12 |
| 3 | Name5/10/40 | 5/10/40 |
| Formeln der Tabelle |
| Zelle | Formel | | B1 | {=TEIL(A1;VERGLEICH(WAHR;ISTZAHL(TEIL(A1;ZEILE($1:$99);1)*1);0);99)} | | B2 | {=TEIL(A2;VERGLEICH(WAHR;ISTZAHL(TEIL(A2;ZEILE($1:$99);1)*1);0);99)} | | B3 | {=TEIL(A3;VERGLEICH(WAHR;ISTZAHL(TEIL(A3;ZEILE($1:$99);1)*1);0);99)} |
|
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen! |
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Klär mich bitte auf wenn ichs falsch verstanden habe.
Gruß Matthias
Betrifft: AW: wenn die /-Zahlen immer am Schluss stehen
von: {mskro}
Geschrieben am: 05.08.2015 11:30:00
Hallo WF,
das sieht schon richtig gut aus, nur fehlt mir der Teil, wo die Zellen ohne einen Schrägstrich betrachtet bzw. mit "-leer-" gekennzeichnet werden.
Gruß Manfred
Betrifft: einfach Länge nach Wechseln abfragen
von: Matthias L
Geschrieben am: 05.08.2015 11:43:12
Hi
| | A | B |
| 1 | Lager1/2/1 | 1/2/1 |
| 2 | Standortname10/8/12 | 10/8/12 |
| 3 | Name5/10/40 | 5/10/40 |
| Formeln der Tabelle |
| Zelle | Formel | | B1 | {=WENN(LÄNGE(WECHSELN(A1;"/";""))<LÄNGE(A1);TEIL(A1;VERGLEICH(WAHR;ISTZAHL(TEIL(A1;ZEILE($1:$99);1)*1);0);99);"")} | | B2 | {=WENN(LÄNGE(WECHSELN(A2;"/";""))<LÄNGE(A2);TEIL(A2;VERGLEICH(WAHR;ISTZAHL(TEIL(A2;ZEILE($1:$99);1)*1);0);99);"")} | | B3 | {=WENN(LÄNGE(WECHSELN(A3;"/";""))<LÄNGE(A3);TEIL(A3;VERGLEICH(WAHR;ISTZAHL(TEIL(A3;ZEILE($1:$99);1)*1);0);99);"")} |
|
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen! |
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Matthias
Betrifft: Super, danke (owt)
von: {mskro}
Geschrieben am: 05.08.2015 11:58:28
Betrifft: oder kürzer ...
von: Matthias L
Geschrieben am: 05.08.2015 12:01:14
Hallo
| | A | C |
| 1 | Test0/8/15 | 0/8/15 |
| 2 | Test0815 | |
| Formeln der Tabelle |
| Zelle | Formel | | C1 | {=WENN(ISTZAHL(FINDEN("/";A1));TEIL(A1;VERGLEICH(WAHR;ISTZAHL(TEIL(A1;ZEILE($1:$99);1)*1);0);99);"")} | | C2 | {=WENN(ISTZAHL(FINDEN("/";A2));TEIL(A2;VERGLEICH(WAHR;ISTZAHL(TEIL(A2;ZEILE($1:$99);1)*1);0);99);"")} |
|
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen! |
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Matthias
Betrifft: Danke Matthias (owt)
von: {mskro}
Geschrieben am: 05.08.2015 12:06:19
Betrifft: Geht auch VBA?
von: {mskro}
Geschrieben am: 06.08.2015 10:13:23
Nochmals Hallo,
kann ich diese Matrixformel, bzw. das Ergebnis aus dieser Formel auch per VBA in eine Variable schreiben?
Gruß Manfred
Beiträge aus den Excel-Beispielen zum Thema "Teile einer Zelle in eine neue Zelle schreiben"
Das Archiv des Excel-Forums
