Daten der Spalte A prüfen;Werte von Datei einlesen

Datei · 2013-03-10T02:02:42+00:00

Hallo in die Runde, folgenden Sachverhalt würde ich gerne lösen können: Mir liegt eine Kolonne von EMailadressen vor. Die Adressen stehen in Spalte A (ab Zelle A2). Es sind ca. 300 Stück. Nun würde ich gerne die Daten meiner Kundendatei (ca. 900 Datensätze in Zeilen) einlesen, wenn die EMail-Adressen übereinstimmen. Auch hier steht die EMail-Adresse in Spalte A. In jeder Zeile der Kundendatei stehen ca. 25 Eintragungen ab Spalte B. Der Code soll nun die Spalte A prüfen und wenn die EMail-Adressen übereinstimmen, sollen die Werte der Zeile aus der Kundendatei ab Spalte B eingelesen werden. Ob der Code die Datei zunächst öffnet oder nicht, ist zweitrangig. Sagen wir die Kundendatei liegt im Ordner *C:/Kunden* und heisst *Kundendaten* Herzlichen Dank für jede Hilfe! Viele Grüße Dietmar aus Aachen

Hallo Dietmar,
an Huberts INDEX Formel ist nichts auszusetzen, ich hätte hier aber eine SVERWEIS Formel genommen.
Warum möchtest du das per VBA lösen, wenn es per Formel so einfach geht? OK, vielleicht brauchst du den Vorgang auf einem Button oder so. Anbei mal ein Code, der dir die gesuchten Werte direkt in die Tabelle schreibt. Im Code verwende ich eine einfache SVERWEIS Formel, statt den ganzen Vorgang zu programmieren. Im Endeffekt macht der Code genau das von Huber vorgeschlagene (Formel schreiben, nach rechts und unten ziehen), nur halt automatisch.

Sub KundendatenEinlesen()
'***** KUNDENDATEI DEFINIEREN *****
Dim sPfad As String
Dim sDatei As String
Dim sTabelle As String
sPfad = "C:\TestTmp"        'ANPASSEN
sDatei = "Kundendaten.xls"  'ANPASSEN
sTabelle = "Tabelle1"       'ANPASSEN
'***** RAHMENBEDINGUNGEN DEFINIEREN ****
Dim iCol As Integer
Dim lRowL As Long
Dim lRowF As Long
Dim iColAnz As Integer
Dim rMail As Range
iCol = 1            'Mailadressen in Spalte 1 (=A)
lRowF = 2           'erste Adresse in Zeile 2 (drüber Überschriften?)
iColAnz = 25        '25 Spalten vergleichen
'**** DATENSÄTZE EINLESEN *****
With ActiveSheet    'ANPASSEN, falls nötig
'letzte Zeile
lRowL = .Cells(.Rows.Count, iCol).End(xlUp).Row
'gesamten Bereich pro Mailadresse durchlaufen
For Each rMail In .Range(.Cells(lRowF, iCol + 1), .Cells(lRowL, iCol + iColAnz))
'Werte per Formel aus Datenbank holen
rMail.FormulaR1C1 = "=VLOOKUP(RC1,'" & sPfad & "\[" & sDatei & "]" & sTabelle & "'! _
R1C1:R65536C" & iColAnz + 1 & "," & rMail.Column & ",)"
'Formel mit Wert ersetzen
rMail.Value = rMail.Value
Next rMail
End With
End Sub

Grüße,
Klaus M.vdT.

Guten Morgen zusammen,
dem Wunsch die Spalte bestimmen zu wollen
Erfüllt: die Variablen dazu heissen iColAb und iVersatz. Erklärung unten.
in einem Datumsfeld erscheint 12:00:00 AM.
Ich behaupte mal, du vertust dich hier. Davon abgesehen dass dies eine UHRZEIT ist (ok, für Excel ist eine Uhrzeit sogar ein Datum) müsste in der Zelle 00:00:00 AM stehen. 12:00:00 AM währe 0,5 und nicht 0.
Es wäre also toll, wenn statt der 0 bzw. 12:00:00 AM gar nichts drin stände.
Erledigt.
Luc:-? überlässt Dir den Vortritt :-)
Oder er versteht den Code nicht ;-) ;-)

Sub KundendatenEinlesen()
'***** KUNDENDATEI DEFINIEREN *****
Dim sPfad As String
Dim sDatei As String
Dim sTabelle As String
sPfad = "C:\TestTmp"        'ANPASSEN
sDatei = "Kundendaten.xls"  'ANPASSEN
sTabelle = "Tabelle1"       'ANPASSEN
'***** RAHMENBEDINGUNGEN DEFINIEREN ****
Dim iCol As Integer
Dim iColAb As Integer
Dim lRowL As Long
Dim lRowF As Long
Dim iColAnz As Integer
Dim rMail As Range
Dim iVersatz As Integer
iCol = 1            'Mailadressen in Spalte 1 (=A)
lRowF = 2           'erste Adresse in Zeile 2 (drüber Überschriften?)
iColAnz = 25        '25 Spalten vergleichen
iColAb = 4          'Trage Werte ab Spalte 2 ein
iVersatz = 2        'Versatz der Spalten im Vergleich zur Datenbank
'**** DATENSÄTZE EINLESEN *****
With ActiveSheet    'ANPASSEN, falls nötig
'letzte Zeile
lRowL = .Cells(.Rows.Count, iCol).End(xlUp).Row
'gesamten Bereich pro Mailadresse durchlaufen
For Each rMail In .Range(.Cells(lRowF, iColAb), .Cells(lRowL, iColAb + iColAnz))
'Werte per Formel aus Datenbank holen
rMail.FormulaR1C1 = _
"=VLOOKUP(RC1,'" & sPfad & "\[" & sDatei & "]" & sTabelle & "'!R1C1:R65536C256," _
& rMail.Column - iVersatz & ",)"
If rMail.Value = 0 Then
'Verweis-Nullen in nichts verwandeln
rMail.Value = ""
Else
'Formel mit Wert ersetzen
rMail.Value = rMail.Value
End If
Next rMail
End With
End Sub

Erklärung iVersatz:
Wenn das Makro "Düsseldorf" ziehen soll, aber stattdessen "40210" zieht (also die PLZ statt dem Ort),
dann ist der Versatz der Spalten zur Datenbank um 1 falsch. iVersatz muss dann entsprechend erhöht werden.
BEISPIEL:
Die Werte werden ab Spalte 4 eingetragen. In der Datenbank stehen die Werte aber ab Spalte 2.
iVersatz ist nun 2, da es zwei Spalten Differenz zwischen Datenbank und Ausgabe gibt.
ich HÄTTE iVersatz auch fix auf iColAb - 2 setzen können, aber ich meine so ist der Code flexibler
an deine Bedürfnisse anpassbar
Pendantische Anmerkung:
Der Versatz + die Anzahl der aus der Datenbank auszulesenden Spalten
dürfen in Summe niemals mehr als 255 ergeben!
sprich, bei 25 Spalten darfst du unter Excel 2003 bis maximal Spalte HW verschieben.
Eine Fehlerbehandlung dafür spare ich mir aber. (Hol dir Xl2010, da gibts 16.000 Spalten)
Grüße,
Klaus M.vdT.

Daten der Spalte A prüfen;Werte von Datei einlesen

Forumthread: Daten der Spalte A prüfen;Werte von Datei einlesen

31
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Daten der Spalte A prüfen;Werte von Datei einlesen

Forumthread: Daten der Spalte A prüfen;Werte von Datei einlesen

31 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

31
Beiträge zum Forumthread

Beiträge zu diesem Forumthread