Microsoft Excel

Herbers Excel/VBA-Archiv

Zahlen mit HG-Farbe summieren

Betrifft: Zahlen mit HG-Farbe summieren von: Heike
Geschrieben am: 26.02.2013 02:01:19

Hallo, guten Morgen ;-)

Habe folgendes Makro, welches auch wunderbar funktioniert, solange NUR Zahlen in gefärbten Zellen sind. Es handelt sich um einen Kalender mit Stundenanzahl, wenn aber der Mitarbeiter Krank ist, wird ein K eingetragen und schon erscheint die Fehlermeldung #WERT

Hat vielleicht jemand Zeit und Lust mal über das Makro zu gucken und es entsprechend zu ändern? Wenn es geht? Ware suuper!

Vielen Dank

Heike

Public Function SummeWennFarbe(Bereich As Range, SuchFarbe As Variant, _
                                Optional Summe_Bereich As Range) As Double

'© Thomas Ramel / 30.05.2003
'Funktion zur Anwendung von SUMMEWENN() mit Hintergrundfare als Kriterium
'Mit angegeben wird eine Zelle mit der gesuchten Hintergrundfarbe oder dem
'entprechende ColorIndex, sowie die üblichen Parameter für SUMMEWENN()

'Zur automatischen Aktualisierung im Tabellenblatt den folgenden Term
'anh ngen: +(0*JETZT()) und F9 drücken
'Also z.B. wie folgt: =SummeWennFarbe(A1;A1:A10)+(0*JETZT())


    Dim intI       As Integer
    Dim intColor   As Integer
    Dim Summe      As Double

    If IsObject(SuchFarbe) Then
       intColor = SuchFarbe(1).Interior.ColorIndex
    Else
       intColor = SuchFarbe
    End If

    If Summe_Bereich Is Nothing Then Set Summe_Bereich = Bereich

    For intI = 1 To Bereich.Count
       If Bereich(intI).Interior.ColorIndex = intColor Then
          Summe = Summe + Summe_Bereich(intI)
       End If
    Next intI

    SummeWennFarbe = Summe
End Function

  

Betrifft: AW: Zahlen mit HG-Farbe summieren von: CitizenX
Geschrieben am: 26.02.2013 02:52:15

Hi,

ersetze:
Summe = Summe + Summe_Bereich(intI)
zu:
Summe = Summe + IIf(IsNumeric(Summe_Bereich(intI)), Summe_Bereich(intI), 0)

Grüße
Steffen


  

Betrifft: Suuuper :-) von: Heike
Geschrieben am: 26.02.2013 09:04:27

Hallo Steffen,

vielen vielen Dank, funktioniert prima.

Wünsche allen einen schönen Tag.

Viele Grüße

Heike


 

Beiträge aus den Excel-Beispielen zum Thema "Zahlen mit HG-Farbe summieren"