Variable für Auswahl mehrerer Tabellenblätter

Bild

Betrifft: Variable für Auswahl mehrerer Tabellenblätter
von: Felix
Geschrieben am: 10.06.2015 23:05:02

Guten Tag,
ich erstelle für eine große Anzahl von Standorten verschiedene Auswertungen in Excel. In den verschiedenen Arbeitsmappen hat jeder Standort jeweils ein Tabellenblatt, bezeichnet mit den Standortkürzeln.
Nun möchte ich die Auswertungen regionsweise in ein pdf exportieren um diese dann den Regionalleitungen in einem definierten Ordner zur Verfügung zu stellen z.B. Regionalleiter Nord bekommt die Tabellenblätter "10 KI", "25 LG" und "26 HH".
Nun habe ich gedacht, dass ich in jeder Arbeitsmappe eine Tabelle "Makro Liste" erstelle, in der ich definiere, welche Tabellenblätter jeweils zusammengestellt werden.
Leider scheiter ich daran eine Variable so zu füttern, dass ich damit die entsprechenden Tabellenblätter auswählen kann:
Sub PdfNachRegion()
Dim varEinrichtung As Variant
Dim lngZeile As Long
Sheets("Makro Liste").Select
lngZeile = 2
Do While lngZeile kleinergleich ActiveSheet.UsedRange.Rows.Count
If lngZeile = 2 Then
varEinrichtung = Range("A" & lngZeile).Value
Else
varEinrichtung = varEinrichtung & " " & Range("A" & lngZeile).Value
End If
lngZeile = lngZeile + 1
Loop
Sheets(Array(varEinrichtung)).Select
Ich bin leider noch zimlicher Anfänger und würde mich sehr über eure Hilfe freuen.
Vielen Dank

Bild

Betrifft: AW: Variable für Auswahl mehrerer Tabellenblätter
von: Sepp
Geschrieben am: 10.06.2015 23:32:21
Hallo Felix,
probier mal.

Sub auswaehlen()
  Dim varSheets() As Variant
  Dim rng As Range
  Dim lngI As Long
  
  With Sheets("Makro Liste")
    For Each rng In .Range("A2:A" & Application.Max(2, .Cells(.Rows.Count, 1).End(xlUp).Row))
      If rng.Value <> "" Then
        Redim Preserve varSheets(lngI)
        varSheets(lngI) = rng.Value
        lngI = lngI + 1
      End If
    Next
  End With
  
  If lngI > 0 Then Sheets(varSheets).Select
  
End Sub


Gruß Sepp


Bild

Betrifft: AW: Variable für Auswahl mehrerer Tabellenblätter
von: Felix
Geschrieben am: 12.06.2015 19:33:52
Hallo Sepp,
das klappt super. Vielen Dank für die schnelle Hilfe!

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Variable für Auswahl mehrerer Tabellenblätter"