Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Auswahl aus zwei Listen mit je zwei Kriterien

Auswahl aus zwei Listen mit je zwei Kriterien
12.06.2014 13:52:04
Arthur
Hi Forum.
Die Eingebung will mir nicht kommen. Für euch sehe ich da noch Hoffnung :o). Und zwar für folgende Aufgabe: Aus zwei Tabellen möchte ich diejenigen Elemente filtern, die bestimmten Kriterien folgen. Beispiel:
Gesucht ist der Index aus Tabelle 1, bei dem ein 'ja' im Attribut steht, wobei der Name in Tabelle 2 mit dem Attribut 'nein' existieren muss.
Tabelle 1
Name Attribut
A ja
B ja
H ja
C nein
Tabelle 2
Name Attribut
G ja
H nein
A nein
C nein
Gewünschtes Ergebnis (Index)
Index Name
1 A
3 H
#nv
#nv
Wie sieht die Formel dafür aus?
Gruß, Arthur

5
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
eine Matrixformel mit INDEX(), ... WECHSELN() ...
12.06.2014 16:05:42
der
Hallo Arthur,
... und nachfolgende Formeln nach unten kopieren. Die #NV´s wolltest Du stehen haben?
 ABCDEFGHI
1NameAttribut NameAttribut  IndexName
2Aja Gja  1A
3Bja Hnein  3H
4Hja Anein  #NV 
5Cnein Cnein  #NV 
6         

Formeln der Tabelle
ZelleFormel
H2=VERGLEICH(I2;A:A;)-1
I2{=WENNFEHLER(INDEX(A:A;KKLEINSTE(WENN(ISTZAHL(VERGLEICH(A$2:A$9&B$2:B$9;D$2:D$9&WECHSELN(E$2:E$9;"nein";"ja"); ))*(A$2:A$9<>""); ZEILE($2:$9)); ZEILE(A1))); "")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Anzeige
AW: eine Matrixformel mit INDEX(), ... WECHSELN() ...
13.06.2014 10:11:01
Arthur
Hallo Werner.
Funktioniert leider nicht. Dennoch Danke. Es kommt mir vor, als dass bspw. der oberste Name immer angezeigt wird. Bei später auftretenden Namen wird das Attribut in Spalte E ignoriert.
Das Zusammenfügen der Spalte und einen anschließenden Vergleich nehme ich aber auf und versuche mich mit Vergleich(... und Wenn(... im Array.
Die #NVs benötige ich nicht unbedingt, kann sie aber nutzen.
Gruß, Arthur

dann solltest Du noch einmal prüfen ...
13.06.2014 14:26:14
der
Hallo Arthur.
... dann sieh einmal (hast Du die Formel in I2 auch als Matrixformel eingegeben?):
 ABCDEFGHI
1NameAttribut NameAttribut  IndexName
2Gnein Gja  3H
3Bja Hnein  5F
4Hja Anein  6A
5Cnein Cnein  9Z
6Fja Fja    
7Aja Zja    
8Mja       
9Xnein       
10Zja       
11         
12         

Formeln der Tabelle
ZelleFormel
H2=WENN(I2="";"";VERGLEICH(I2;A:A;)-1)
I2{=WENNFEHLER(INDEX(A:A;KKLEINSTE(WENN(ISTZAHL(VERGLEICH(A$2:A$99&B$2:B$99;D$2:D$99&WECHSELN(E$2:E$99;"nein";"ja"); ))*(A$2:A$99<>""); ZEILE($2:$99)); ZEILE(A1))); "")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Anzeige
AW: dann solltest Du noch einmal prüfen ...
13.06.2014 17:33:25
Arthur
Hallo Werner.
Die Formel war als Matrix eingegeben, hat aber irgendwie nicht wollen. Nicht weiter schlimm, denn die Antwort hat mir dennoch geholfen vom Schlauch zu kommen, auf dem ich gestanden war. Meine Lösung sieht nun so aus:
G2 : 0
H2 : =ANZAHL2($A$2:$A$15)
G3++ : {=VERGLEICH(1;WENNFEHLER(VERGLEICH(BEREICH.VERSCHIEBEN($A$2:$A$15;$G2+1;0;$H$2-$G2;1);WENN(BEREICH.VERSCHIEBEN($E$2;0;0;$H$2;1)<>"ja";BEREICH.VERSCHIEBEN($D$2;0;0;$H$2;1);"#");0)>$G2;0)*1;0)+$G2}
H3++ : =INDEX($A$2:$A$15;G3)
Gruß, Arthur

dann vergleiche doch noch einmal ...
13.06.2014 18:15:04
der
Hallo Artur,
... und zwar am nachfolgenden Datenbeispiel.
Deine Formeln stehen wie von Dir angegeben in H2 sowie G3:H3.
Meine Lösungsformeln stehen in J2:K2 und entsprechend Deinen mir bisher bekannten Bedingungsvorgaben. Mit Deinen Formeln wird danach falsch "B" ausgewiesen und "A" und "F" ignoriert.
 ABCDEFGHIJK
1NameAttribut NameAttribut    IndexName
2Gnein Gja 09 3H
3Bja Hnein 2B 5F
4Hja Anein 3H 6A
5Cnein Cnein 9Z 9Z
6Fja Fja #NV#NV   
7Aja Zja      
8Mja         
9Xnein         
10Zja         

Formeln der Tabelle
ZelleFormel
H2=ANZAHL2($A$2:$A$15)
J2=WENN(K2="";"";VERGLEICH(K2;A:A;)-1)
K2{=WENNFEHLER(INDEX(A:A;KKLEINSTE(WENN(ISTZAHL(VERGLEICH(A$2:A$99&B$2:B$99;D$2:D$99&WECHSELN(E$2:E$99;"nein";"ja"); ))*(A$2:A$99<>""); ZEILE($2:$99)); ZEILE(A1))); "")}
G3{=VERGLEICH(1;WENNFEHLER(VERGLEICH(BEREICH.VERSCHIEBEN($A$2:$A$15;$G2+1;0;$H$2-$G2;1); WENN(BEREICH.VERSCHIEBEN($E$2;0;0;$H$2;1)<>"ja";BEREICH.VERSCHIEBEN($D$2;0;0;$H$2;1); "#"); 0)>$G2;0)*1;0)+$G2}
H3=INDEX($A$2:$A$15;G3)
J3=WENN(K3="";"";VERGLEICH(K3;A:A;)-1)
K3{=WENNFEHLER(INDEX(A:A;KKLEINSTE(WENN(ISTZAHL(VERGLEICH(A$2:A$99&B$2:B$99;D$2:D$99&WECHSELN(E$2:E$99;"nein";"ja"); ))*(A$2:A$99<>""); ZEILE($2:$99)); ZEILE(A2))); "")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...
Anzeige

332 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige