menuleiste mit dokument versenden



Excel-Version: 97/2000
  

Re: menuleiste mit dokument versenden

von: Hajo
Geschrieben am: 14.04.2002 - 13:44:10


Hallo Andreas

eine Möglichkeit wäre die Symbolleiste in der Datei erzeugen. Wobei hinter OnAction das Makro steht das in einem Modul ist. Folgenden Code in DieseArbeitsmappe.


Private Sub Workbook_Open()
    Dim cb As CommandBar
    Dim CBC As CommandBarButton
    Dim I%
    On Error Resume Next
    Set cb = Application.CommandBars.Add(Name:="Preisliste1", _
        temporary:=True, Position:=msoBarTop)
    On Error GoTo 0
    If Application.CommandBars("Preisliste1").Visible = False Then
        cb.Visible = True
        For I = 1 To 15
            Set CBC = cb.Controls.Add(Type:=msoControlButton)
            With CBC
                .Width = 50                 ' Breite der Schalter
                .Style = msoButtonCaption   ' Text auf Schaltfläche
                Select Case I
                    Case 1
                        .Caption = "IRB"
                        .OnAction = "Roboter"
                        .TooltipText = "Roboter einfügen"
                    Case 2
                        .Caption = "Ent."
                        .OnAction = "Entlader"
                        .TooltipText = "Entlader einfügen"
                    Case 3
                        .Caption = "LPM"
                        .OnAction = "LPM"
                        .TooltipText = "LPM einfügen"
                    Case 4
                        .Caption = "Bel."
                        .OnAction = "Belader"
                        .TooltipText = "Belader einfügen"
                    Case 5
                        .Caption = "PTS"
                        .OnAction = "PTS"
                        .TooltipText = "PTS Einfügen"
                    Case 6
                        .Caption = "KTS"
                        .OnAction = "Gebindetransport"
                        .TooltipText = "Gebindetransport einfügen"
                    Case 7
                        .Caption = "S.S."
                        .OnAction = "SS"
                        .TooltipText = "Schalt- und Steuerausrüstung einfügen"
                    Case 8
                        .Caption = "Aus."
                        .OnAction = "Auspacker"
                        .TooltipText = "Auspacker einfügen"
                    Case 9
                        .Caption = "Ein."
                        .OnAction = "Einpacker"
                        .TooltipText = "Einpacker einfügen"
                    Case 10
                        .Caption = "ET60.1"
                        .OnAction = "ET601"
                        .TooltipText = "ET 60.1 einfügen"
                    Case 11
                        .Caption = "ET 85"
'                        .OnAction = "ET85"
'                        .TooltipText = "ET 85 einfügen"
                        .Enabled = False
                    Case 12
                        .Caption = "Kopfpa."
                        .OnAction = "Kopfpalette"
                        .TooltipText = "Kopfpalettenaufleger einfügen"
                    Case 13
                        .Caption = "NGA"
                        .OnAction = "NGA"
                        .TooltipText = "Neuglasabheber einfügen"
                    Case 14
                        .Caption = "NGS"
                        .OnAction = "NGS"
                        .TooltipText = "Neuglasabschieber einfügen"
                    Case 15
                        .Caption = "Zu."
                        .OnAction = "Zukauf"
                        .TooltipText = "Zukauf einfügen"
                End Select
            End With
        Next I
    End If
End Sub

Private Sub Workbook_Deactivate()
    On Error Resume Next
    If Application.CommandBars("Preisliste1").Visible = True Then
        Application.CommandBars("Preisliste1").Visible = False
    End If
End Sub

Private Sub Workbook_Activate()
    On Error GoTo neu
    If Application.CommandBars("Preisliste1").Visible = False Then
        Application.CommandBars("Preisliste1").Visible = True
    End If
    Exit Sub
neu:
    Workbook_Open
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    On Error Resume Next
    Application.CommandBars("Preisliste1").Delete
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Excel.Range)
    On Error GoTo neu
    If Application.CommandBars("Preisliste1").Visible = False Then
        Application.CommandBars("Preisliste1").Visible = True
    End If
    Exit Sub
neu:
    Workbook_Open
End Sub

Gruß Hajo

  

super, danke

von: andreas
Geschrieben am: 14.04.2002 - 14:03:53


nach unten

Betrifft: menuleiste mit dokument versenden
von: andreas
Geschrieben am: 14.04.2002 - 13:20:55

hallo
im forum habe ich mal einen beitrag gelesen, wonach es möglich ist eine menuleiste an ein dokument zu binden und auch mit diesem per email zu versenden. leider finde ich den beitrag nicht mehr.

kann mir jemand helfen? wie lautet dieser code?

besten dank
gruss andi


 nach oben

Beiträge aus den Excel-Beispielen zum Thema "menuleiste mit dokument versenden"