HERBERS Excel-Forum - das Archiv

Thema: Datedif wenn kein kein Jahr dann nicht anzeigen

Datedif wenn kein kein Jahr dann nicht anzeigen
Heinz H
Schönen Sonntag im Forum,

Frage: ich habe die Formel 
=DATEDIF(E3;G3;"Y")& " Jahre "&DATEDIF(E3;G3;"YM")&" Monate "&DATEDIF(E3;G3;"MD")&" Tage"


Funktioniert auch, gibt es eine Möglichkeit wenn "0 Jahre herauskommt das man dann nur Monate und Tage angezeigt bekommt.
Also ohne 0 Jahre ?

Danke
Heinz

Als Ansatz
RPP63
 EF
222 Jahre
30 
411 Jahre

ZelleFormel
F2=TEXT(E2;"0 \Ja\hr\e;;")
F3=TEXT(E3;"0 \Ja\hr\e;;")
F4=TEXT(E4;"0 \Ja\hr\e;;")


Gruß Ralf
AW: Datedif wenn kein kein Jahr dann nicht anzeigen
Daniel
=Wenn(DATEDIF(E3;G3;"Y")=0;"";DATEDIF(E3;G3;"Y")& " Jahre ")&DATEDIF(E3;G3;"YM")&" Monate "&DATEDIF(E3;G3;"MD")&" Tage"

Gruß Daniel
AW: DateDif Jahr 0 nicht anzeigen und Pluralbildung
daniel
Noch ne möglichkeit, hier fallen auch 0 Monate oder 0 Tage weg, außerdem kein Plural bei 1. 

=LET(d;DATEDIF(E3;G3;{"Y";"YM";"MD"});TEXTVERKETTEN(" ";1;WENN(d=0;"";d&{" Jahr";" Monat";" Tag"}&WENN(d>1;"e";""))))


Gruß Daniel
AW: SUPER Daniel
Heinz H
Hallo Daniel,

Das ist genial !!

Recht herzlichen Dank

SG, Heinz
Danke an Ralf & Daniel
Heinz H
Hallo Ralf & Daniel,

Funktioniert wie gewünscht.

Danke !!!

Wünsche noch einen schönen Sonntag

Heinz