Datum

Titel

19.04.2024 10:59:29

Datei Auswählen und öffnen

19.04.2024 10:46:47

Bestimmte Zellen aus dynamischer Liste zurückgeben

19.04.2024 10:39:36

Schaltfläche auf einem Tabellenblatt NICHT mit abspeichern

19.04.2024 09:26:26

Median für Zeilen mit gleichen Zeitstempel

Du findest keine passende Antwort auf Deine Frage?

Stelle Deine Frage in unserem Live-Forum

Archiv - Navigation

544to548

Aktuelles Verzeichnis

Verzeichnis Index

Übersicht Verzeichnisse

Vorheriger Thread

Rückwärts Blättern

Nächster Thread

Vorwärts blättern

HERBERS

Excel-Forum (Archiv)

20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender

Rückwärts Blättern

Aktuelles Verzeichnis

Übersicht Verzeichnisse

Vorwärts blättern

Inhaltsverzeichnis

ZÄHLENWENN mit 2 Bedingungen

Forumthread: ZÄHLENWENN mit 2 Bedingungen
16 Beiträge zu diesem Forumthread
Anzeige
310 Threads zu ähnlichen Themen
VBA Beispiele zu verwandten Themen

Top 100 Forumthreads

10.01.2005 20:28:54

Udo

Hallo,
ZÄHLENWENN mit 2 Bedingungen hab ich schon Probiert, funktioniert aber nur bei ganzen Zellinhalten. Ich bräuchte aber eine Formel die angibt wie oft ein Name aus einer Adresse in ein bestimmtes Jahr (Bsp. 2000) vorhanden ist.
In Spalte A steht das Datum
In Spalte B stehen die Adressen
Gesucht wird z.b. "Udo xyName" aus dem Jahr "2000"
Spalte A : Spalte B
05.08.1999 : Vorname Name, xxStraße 12, 14141 Stadt
08.10.2000 : Peter Pan, Straße 123, 12345 Ort
10.10.2000 : Udo xyName, yxStraße 184, 25874 xyOrt
05.11.2001 : Hans Guckindeiluft, SperberSt. 5, 99999 Buxtehude
09.12.2000 : Udo xyName, yxStraße 184, 25874 xyOrt
Im diesem Beispiel also 2 mal, nur wie kann man das per Formel Realisieren?
Gruß Udo

16
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: ZÄHLENWENN mit 2 Bedingungen

Hübi
AW: ZÄHLENWENN mit 2 Bedingungen

Reinhard
AW: ZÄHLENWENN mit 2 Bedingungen

Hübi
ZÄHLENWENN mit 2 Bedingungen&finden()

ransi
AW: ZÄHLENWENN mit 2 Bedingungen&finden()

10.01.2005 21:33:32

Udo
freut mich aber...

ransi
AW: oder so...

FP
AW: oder so...

Hübi
AW: kleine Korrektur

FP
AW: ZÄHLENWENN mit 2 Bedingungen

10.01.2005 21:23:22

Udo
AW: ZÄHLENWENN mit 2 Bedingungen

Hübi
AW: ZÄHLENWENN mit 2 Bedingungen

10.01.2005 21:48:25

Udo
Ähm... hätte da noch mal ne Frage.

10.01.2005 22:42:37

Udo
AW: Ähm... hätte da noch mal ne Frage.

Hübi
DANKE euch!! Man seit ihr GUT

10.01.2005 23:44:43

Udo
noch einer drauf, falls es dich interessiert

Hübi

AW: ZÄHLENWENN mit 2 Bedingungen

Hübi

Hi Udo,
meinst du es so

Tabelle2

	A	B	C	D	E	F
1	Datum	Name		Anzahl	Name	Jahr
2	02.02.2004	Schulz		3	Schulz	2004
3	25.08.2004	Meier
4	17.03.2004	Schulz
5	24.07.2005	Schulz
6	19.08.2004	Schulz

Formeln der Tabelle

D2 : {=SUMMENPRODUKT((JAHR(A2:A20)=F2)*(B2:B20=E2))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß Hübi

AW: ZÄHLENWENN mit 2 Bedingungen

Reinhard

Hallo Hübi,
nach ganzen Strings suchen kann Udo wohl, er sucht eine Lösung für Teilstringsuche
quasi in Tabellen wie dieser nach 2000 und *Udo* suchen. SpalteA SpalteB SpalteC 05.08.1999 Vorname Name, xxStraße 12, 14141 Stadt 08.10.2000 Peter Pan, Straße 123, 12345 Ort 10.10.2000 Udo xyName, yxStraße 184, 25874 xyOrt 05.11.2001 Hans Guckindeiluft, SperberSt. 5, 99999 Buxtehude 09.12.2000 Udo xyName, yxStraße 184, 25874 xyOrt
Gruß
Reinhard

AW: ZÄHLENWENN mit 2 Bedingungen

Hübi

Hi Reinhard,
der Schritt von ganzem Text zu Teil-String ist nicht zu schwer.
Hatte mich aber von seinem Level leiten lassen - und da ist nun einmal Summenprodukt nicht selbstverständlich?!
Was sagst du hierzu?

Tabelle2

	A	B	C	D	E	F
1	Datum	Name		Anzahl	Name	Jahr
2	02.02.2004	Udo Schulz, Weg1		3	Udo Schulz	2004
3	25.08.2004	Klaus Meier, Weg 2
4	17.03.2004	Udo Schulz, Weg2
5	24.07.2005	Udo Schulz, Weg1
6	19.08.2004	Udo Schulz, Weg4

Formeln der Tabelle

D2 : {=SUMMENPRODUKT((JAHR(A2:A6)=F2)*(LINKS(B2:B6;FINDEN(",";B2:B6)-1)=E2))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß Hübi

ZÄHLENWENN mit 2 Bedingungen&finden()

ransi

hallo udo
schau mal hier:

	A	B	C
19	05.08.1999	Vorname Name, xxStraße 12, 14141 Stadt	2
20	08.10.2000	Peter Pan, Straße 123, 12345 Ort
21	10.10.2000	Udo xyName, yxStraße 184, 25874 xyOrt
22	05.11.2001	Hans Guckindeiluft, SperberSt. 5, 99999 Buxtehude
23	09.12.2000	Udo xyName, yxStraße 184, 25874 xyOrt

Formeln der Tabelle

C19 : {=SUMME((JAHR(A19:A23)=2000)*WENN(ISTFEHLER(FINDEN("Udo xyName";B19:B23;1)>0);0;FINDEN("Udo xyName";B19:B23;1)=1))}

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
ransi

AW: ZÄHLENWENN mit 2 Bedingungen&finden()

10.01.2005 21:33:32

Udo

Hallo ransi
JAAAAAAAAAA, Perfekt
Danke dir vielmals dafür, wäre ich niemals drauf gekommen.
Gruße an alle Udo

freut mich aber...

ransi

..änder die formel mal so ab:
C19 : {=SUMME((JAHR(A19:A23)=2000)*WENN(ISTFEHLER(FINDEN("Udo xyName";B19:B23;1)&gt0);0;FINDEN("Udo xyName";B19:B23;1)&gt0))}
also am schluss das "=1" durch "&gt0" ersetzen.
dann gehts auch wenn der name nicht an erster stelle steht sondern
irgendwo im string.
ransi

AW: oder so...

Hi ransi,

Tabelle1

	A	B	C	D	E	F	G
1	Datum	Name		gefunden	Jahr	Name
2	17.12.2004	CVXaver Schulz		4	2004	Schulz
3	05.12.2004	Richard Schulz, abc		4
4	01.01.2005	Schulz, abc		gefunden	Monat	Jahr	Name
5	13.11.2004	Dr.H. Schulz, Dingsda		1	11	2004	Schulz
6	05.12.2004	Schuld war
7	09.12.2004	VXFSchulzZY
8	23.11.2004	VJM
9	12.11.2004	SJH
10	07.01.2005	THX
11	02.01.2005	YXT
12	18.12.2004	EEJ
13	24.12.2004	MIJ
14	22.11.2004	WWL
15	01.01.2005	HBR
16	12.11.2004	TAU
17	20.11.2004	WBT
18	23.12.2004	IZQ
19	14.12.2004	EPS
20	15.11.2004	CMM
21	21.11.2004	KSG

Formeln der Tabelle

D2 : {=SUMME((JAHR(A2:A21)=E2)*((LÄNGE(B2:B21)-LÄNGE(WECHSELN(B2:B21;F2;"")))>0))}
D3 : {=ANZAHL(WENN(JAHR(A2:A21)=E2;SUCHEN(F2;B2:B21)))}
D5 : {=ANZAHL(WENN(TEXT(A2:A21;"MMJJJJ")=E5&F5;SUCHEN(G5;B2:B21)))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Servus aus dem Salzkammergut
Franz

AW: oder so...

Hübi

Hi Franz,
sehr interessant und logisch, wie du es gelöst hast - Kompliment.
Gruß Hübi

AW: kleine Korrektur

Hi Hübi,
damit die Formel in D5 auch bei gesuchtem Monat 1 - 9 funktioniert:
{=ANZAHL(WENN(TEXT(A2:A21;"MJJJJ")=E5&F5;SUCHEN(G5;B2:B21)))}
Servus aus dem Salzkammergut
Franz

AW: ZÄHLENWENN mit 2 Bedingungen

10.01.2005 21:23:22

Udo

Hallo Hübi,
Jaein, das Problem ist das ich aus Spalte B nur den Namen (also quasi ein Teilstring) aus der ganzen Adresse zählen muss.
Da im originalen manchmal die Adresse mehrfach untereinander stehen und da nicht immer die ganze Adresse steht, sondern
1.Zeile : Udo yxName, yxStraße 123, 12345 yxOet
2.Zeile : Udo yxName, siehe oben
3.Zeile : Udo yxName, siehe oben
4.Zeile : usw. usw.
Das Beispiel von dir zählt nur ganze Zellinhalte.
Gruß Udo

AW: ZÄHLENWENN mit 2 Bedingungen

Hübi

Hi Udo,
in diesem Beispiel wird noch der Name extrahiert

Tabelle2

	A	B	C	D	E	F
1	Datum	Name		Anzahl	Name	Jahr
2	02.02.2004	Schulz, Weg1		3	Schulz	2004
3	25.08.2004	Meier, Weg 2
4	17.03.2004	Schulz, Weg1
5	24.07.2005	Schulz, Weg1
6	19.08.2004	Schulz, Weg1

Formeln der Tabelle

D2 : {=SUMMENPRODUKT((JAHR(A2:A6)=F2)*(LINKS(B2:B6;FINDEN(",";B2:B6)-1)=E2))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß Hübi

AW: ZÄHLENWENN mit 2 Bedingungen

10.01.2005 21:48:25

Udo

Hallo Hübi,
JAAAAA, ebenfalls Perfekt.
Auch an dich ein ganz großes Dankeschön.
Gruß Udo

Ähm... hätte da noch mal ne Frage.

10.01.2005 22:42:37

Udo

Hallo ich noch mal,
Wenn ich nach Monat / Jahr und den Name aus der Adresse suchen möchte wie bewerkstellige ich dieses?
Gruß Udo

AW: Ähm... hätte da noch mal ne Frage.

Hübi

Hi Udo,
ich hoffe, du meinst es so

Tabelle2

	A	B	C	D	E	F	G
1	Datum	Name		Anzahl	Name	Jahr	Monat
2	02.08.2004	Udo Schulz, Weg1		2	Udo Schulz	2004	8
3	25.08.2004	Klaus Meier, Weg 2
4	17.03.2004	Udo Schulz, Weg2
5	24.07.2005	Udo Schulz, Weg1
6	19.08.2004	Udo Schulz, Weg4

Formeln der Tabelle

D2 : {=SUMMENPRODUKT((JAHR(A2:A6)=F2)*(MONAT(A2:A6)=G2)*(LINKS(B2:B6;FINDEN(",";B2:B6)-1)=E2))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß Hübi

DANKE euch!! Man seit ihr GUT

10.01.2005 23:44:43

Udo

Vielen, vielen Dank
Grüße Udo

noch einer drauf, falls es dich interessiert

Hübi

Hi Udo;
wenn du das Prinzip verstanden hast, noch einer drauf:

Tabelle2

	A	B	C	D	E	F	G
1	Datum	Name		Anzahl	Name	Jahr	Monat
2	02.08.2004	Udo Schulz, Weg1		3	Udo Schulz	2004	8
3	25.08.2004	Klaus Meier, Weg 2
4	17.03.2004	Udo Schulz, Weg2
5	24.07.2005	Udo Schulz, Weg1		In diesem Beispiel kannst du Einträge in Sp. A und B ergänzen, ohne die Formel ändern zu müssen. Allerdings muss die Zeile ausgefüllt sein !!!
6	19.08.2004	Udo Schulz, Weg4
7	22.08.2004	Udo Schulz, Weg 22
8	13.08.2005	Udo Schulz, Straße 33
9	17.08.2005	Udo Schulz, Auch Noch Da

Formeln der Tabelle

D2 : {=SUMMENPRODUKT((JAHR(INDIREKT("A2:A"&ANZAHL2(A:A)))=F2)*(MONAT(INDIREKT("A2:A"&ANZAHL2(A:A)))=G2)*(LINKS(INDIREKT("B2:B"&ANZAHL2(A:A));FINDEN(",";INDIREKT("B2:B"&ANZAHL2(A:A)))-1)=E2))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß Hübi