Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
1672to1676
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Drei Tabellen(oder Spalten) - gleiche Werte

Drei Tabellen(oder Spalten) - gleiche Werte
13.02.2019 18:21:37
Adam
Hallo liebe Leut,
eigentlich dachte ich, ich würde zahlreiche Beiträge im Netz hierzu finden. Entweder es gibt wirklich nicht so viel oder ich habe nach dem falschen Begriff gesucht:
Es gibt drei Spalten mit teilweise verschiedenen und teilweise gleichen Begriffen.
Ich möchte einfach nur wissen, welcher dieser Begriffe in allen drei Spalten vorkommt. Quasi wie die Funktion VERGLEICH nur eben auf drei Spalten erweitert.
Alternativ zu den Spalten können es auch drei Tabellen einer Datei sein.
Danke schon mal für die Hilfe.

19
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Drei Tabellen(oder Spalten) - gleiche Werte
13.02.2019 18:45:26
ChrisL
Hi Adam
geht sicher auch kürzer, aber ich denke so müsste es funktionieren
=WENN(UND(ZÄHLENWENN(A:A;Suchkriterium);ZÄHLENWENN(B:B;Suchkriterium);ZÄHLENWENN(C:C;Suchkriterium)); "3x";"nix")
cu
Chris
AW: Drei Tabellen(oder Spalten) - gleiche Werte
13.02.2019 19:11:31
Günther
Moin,
"Ich möchte einfach nur wissen, welcher dieser Begriffe in allen drei Spalten vorkommt."
interpretiere ich so: Hilfsspalte D:, dort diese Formel:

=A1=B1=C1
und dann nach WAHR filtern. Oder per Power Query.
"Alternativ zu den Spalten können es auch drei Tabellen einer Datei sein."
verstehe ich nicht ... :-(
Gruß
Günther
Anzeige
AW: sieh dazu mal mein Beitrag owT
13.02.2019 19:17:23
neopa
Gruß Werner
.. , - ...
AW: nachgefragt ...
13.02.2019 19:07:00
neopa
Hallo Adam,
... sind die Begriffe aber je Spalte eineindeutig oder können diese dort auch als Duplikate vorhanden sein. Letzteres würde die Auswertung erheblich erschweren. Denn ich hab Dich so verstanden, dass Du erst die Begriffe ermitteln willst, die zumindest einmal in jeder Spalte vorhanden sind.
Gruß Werner
.. , - ...
AW: diese Frage hat sich nun erledigt owT
13.02.2019 20:18:57
neopa
Gruß Werner
.. , - ...
AW: nachgefragt ...
14.02.2019 11:55:48
Adam
Danke für den Hinweis. An Duplikate hatte ich nicht gedacht. In meinem Fall kommt pro Spalte jeder Wert nur einmal vor - von daher ist es kein Problem.
Wenn die Werte jedoch mehrmals pro Spalte vorhanden wären, würde ich die Spalte erst mal bereinigen indem ich die Duplikate lösche. Das sollte dann funktionieren.
Anzeige
AW: dann nur 1 Matrixfunktion(alität)sformel ...
14.02.2019 13:35:34
neopa
Hallo Adam,
... und ohne Hilfsspalte in E2:
=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE(A$2:A$99)/(ZÄHLENWENN(B$2:C$99;A$2:A$99)=2);ZEILE(A1)));"")
und diese nach unten kopieren
Gruß Werner
.. , - ...
AW: AGGREGAT() in einer klass. Matrixformel ...
13.02.2019 20:18:16
neopa
Hallo Adam,
... normalerweise benötigen AGGREGAT() keinen klassischen Matrixformelabschluss. So auch nicht in E2. Dagegen wegen der Spezifika der Formellösung der Hilfsspalte (hielt ich für notwendig, um evtl. vorhandene Duplikate in den Datenspalten "auszufiltern") in H2 schon
Mit der Formel sollten auch nicht viele zig-tausende Datensätze ausgewertet werden. Momentan hab ich den Auswertungsbereich deswegen auch auf Zeile 99 beschränkt. Beide Formeln entsprechend weit nach unten kopieren.
Arbeitsblatt mit dem Namen 'Tabelle2'
 ABCDEFGH
1S1S2S3 Ergebnis  Hilfsspalte
2ada x  x
3bex b  x
4cxb y  b
5xby    b
6yyb    y
7 ya     
8 ex     
9 b      
10        

ZelleFormel
E2=WENNFEHLER(INDEX(H:H;AGGREGAT(15;6;ZEILE(C$2:C$99)/(VERGLEICH(H$2:H$99;H$2:H$99;0)=ZEILE(C$2:C$99)-1);ZEILE(E1)))&"";"")
H2{=WENNFEHLER(INDEX(B:B;AGGREGAT(15;6;VERGLEICH(1&C$2:C$99;ISTZAHL(VERGLEICH(B$2:B$99;A$2:A$99;0))+0&B$2:B$99;0);ZEILE(A1))+1);"")}
Achtung, Matrixformel enthalten!
Die geschweiften Klammern{} werden nicht eingegeben.
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Gruß Werner
.. , - ...
Anzeige
AW: AGGREGAT() in einer klass. Matrixformel ...
13.02.2019 20:41:24
Luschi
Hallo Werner,
daß ich das noch erleben durfte, Matrix-Funktionalitäts-Funktionen mit Userbild
Abschluß - Donnerwetter!
Gruß von Luschi
aus klein-Paris
Nicht gleich übermütig wdn, ...
14.02.2019 00:35:13
Luc:-?
…Luschi; ;-)
das beweist nur, dass diese Matrixfunktionalitätsformeln (eigentl eher ~Fktt) nicht so den MatrixFml-Abschluss vermeidend sind, wie gemeinhin angenommen wird - auch nicht AGGREGAT! Das gelänge viell mit der generellen Vermeidung per FmlText-Interpreter in den neuesten Xl-Versionen, oder aber mit diesem UDF-Nachbau:
H2[:H6]:=WENNFEHLER(INDEX(B:B;AggregateXk(-15;6;VERGLEICH(1&C$2:C$99;ISTZAHL(VERGLEICH(B$2:B$99;A$2:A$99;0))+0&B$2:B$99;0);ZEILE(A1))+1);"")
Morhn, Luc :-?
„Die Intelligenzmenge ist auf diesem Planeten eine Konstante, die Bevölkerung nimmt aber zu!“ Auch deshalb informieren mit …
Anzeige
abartig kompliziert ?
13.02.2019 22:10:30
WF
Hi,
in H2:
=WENN(ZÄHLENWENN(B$2:B$99;A2)*ZÄHLENWENN(C$2:C$99;A2);A2;"")
in E2 die Arrayformel:
{=WENNFEHLER(INDEX(H$2:H$99;VERGLEICH(1;(ZÄHLENWENN(M$1:M1;H$2:H$99)=0)*(H$2:H$99"");0));"")}
beide runterkopieren
WF
hatte das Ergebnis in M
13.02.2019 22:16:41
WF
die Arrayformel in E2 lautet logischerweise:
=WENNFEHLER(INDEX(H$2:H$99;VERGLEICH(1;(ZÄHLENWENN(E$1:E1;H$2:H$99)=0)*(H$2:H$99"");0));"")
WF
AW: ja; mit kompl. Hilfsspalte & ZÄHLENWENN() ...
14.02.2019 12:55:37
neopa
Hallo WF,
... ist es natürlich einfacher.
Ich hatte mich gestern Abend zu sehr mit VERGLEICH() verrannt, weil ich es zunächst ganz ohne Hilfsspalte lösen wollte. Dafür brauchte ich VERGLEICH() und hatte erst in den letzten 5 Minuten gemerkt, dass ich als Ergebnis dann trotzdem Dublettenergebniswerte bekommen könnte.
Jedoch mit Deiner ZÄHLENWENN()Formel für die Hilfsspalte H (die im Gegensatz zu meiner bisherigen, natürlich über den max. Datenbereich kopiert werden muss) würde ich dann auch das Ergebnislisting ohne klassische Matrixformel lösen.
E1: Leerzelle und in E2:
=WENNFEHLER(INDEX(H:H;AGGREGAT(15;6;ZEILE(A$2:A$99)/(ZÄHLENWENN(E$1:E1;H$2:H$99)=0);1))&"";"")
und nach unten kopieren.
Gruß Werner
.. , - ...
Anzeige
über den max. Datenbereich hinaus kopieren ?
14.02.2019 13:18:26
WF
Nee - ich hab Spalte A ausgesucht. Dann nur bis zum letzten Eintrag von A.
WF
AW: "hinaus" hab ich nicht geschrieben owT
14.02.2019 13:37:16
neopa
Gruß Werner
.. , - ...
AW: Drei Tabellen(oder Spalten) - gleiche Werte
14.02.2019 08:12:03
Daniel
Hi
wenn es dir reicht, in einer der Spalten die Kandidaten zu markieren, dann such dir irgendeine Spalte aus (am besten die kürzeste) und schreibe in deren Nachbarspalte folgende Formel, um die Werte zu markieren, die in allen drei Spalten vorkommen.
ich gehe für das Beispiel mal davon aus, dass es die Spalten A-C sind und wir prüfen in Spalte C:
=Wenn(UND(IstZahl(Vergleich(C1;A:A;0));IstZahl(Vergleich(C1;B:B;0)));"x";"")
dann sind in Spalte D alle Werte aus C, die auch in A und B vorkommen, mit einem "x" markiert.
Gruß Daniel
Anzeige
das war bei mir einfacher
14.02.2019 08:52:37
WF
=WENN(ZÄHLENWENN(B:B;C1)*ZÄHLENWENN(A:A;C1);"x";"")
WF
wenns ein Performance-Problem gibt
14.02.2019 12:09:15
Daniel
sollte VERGLEICH etwas schneller sein als ZÄHLENWENN.
Gruß Daniel
AW: Drei Tabellen(oder Spalten) - gleiche Werte
14.02.2019 11:50:15
Adam
Ich danke euch allen für die Hilfe.
Konnte erst jetzt schreiben. Es sind viele gute Möglichkeiten dabei. Wobei ich zu der Zählenwenn-Variante neige, da ich dieses zumindest gut nachvollziehen kann.
Manch andere Formeln sind mir entweder neu oder ich muss mich jetzt erst noch etwas intensiver damit beschäftigen.

308 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige