Zählenwenn (?) mit unbekannter Suchspalte

Bild

Betrifft: Zählenwenn (?) mit unbekannter Suchspalte
von: Joerschi
Geschrieben am: 17.07.2015 10:11:37

Hallo liebes Forum,
folgendes möchte ich per Formel lösen (Skizze + Beispieldatei unten):
Es gibt eine Datentabelle mit vielen Einträgen und mehreren Spalten mit jeweils unterschiedlichen Spaltenüberschriften.
Manuell gibt man einen Zahlenwert vor (Zelle B1 im Beispiel).
Außerdem in Zelle B2 und C2 die Überschriften der Spalten, auf welche nachfolgende Kriterien zutreffen sollen.
Per Zählenwenn (oder andere Funktino) soll nun in Zelle H1 ermittelt werden, wie viele Einträge es z. B. gibt, wo die Werte in den in B2/C2
definierten Datenspalten(überschriften) den in Zelle B1 vorgegebenen Wert übersteigen - und zwar gleichzeitig je Zeile!
Beispiel:
Userbild

grün unterlegt sind alle Werte größergleich Vorgabe.
Rote Schrift sind alle Werte, die gleichzeitig (in einer Zeile) in den vorgegebenen Überschriften auftauchen. Also was gesucht ist.
Die Lösung im Beispiel wäre "4".

Musterdatei: https://www.herber.de/bbs/user/98886.xlsx
Hätte jemand einen Tip?
Danke im Voraus und beste Grüße
joerschi

Bild

Betrifft: AW: Zählenwenn (?) mit unbekannter Suchspalte
von: Rudi Maintaire
Geschrieben am: 17.07.2015 10:20:01
Hallo,
Matrixformel:
{=SUMME((INDEX(B5:K12;;VERGLEICH(B2;B4:K4;))>=B1)*(INDEX(B5:K12;;VERGLEICH(C2;B4:K4;))>=B1))}
Gruß
Rudi

Bild

Betrifft: AW: Zählenwenn (?) mit unbekannter Suchspalte
von: Joerschi
Geschrieben am: 17.07.2015 10:30:45
Dank Dir Rudi. Kurz und knackig.
Kann man gut adaptieren und ergänzen.
Liebe Grüße
joerschi

Bild

Betrifft: AW: Zählenwenn (?) mit unbekannter Suchspalte
von: coachyou
Geschrieben am: 17.07.2015 10:28:43
Hallo joerschi,
versuch mal folgende Matrixformel:
=SUMME((((BEREICH.VERSCHIEBEN($A$5:$A$12;;VERGLEICH($B$2;$B$4:$K$4;0))>$B$1)+(BEREICH.VERSCHIEBEN($A$5:$A$12;;VERGLEICH($C$2;$B$4:$K$4;0))>$B$1))>=2)*1)
Gruß coachyou

Bild

Betrifft: AW: Zählenwenn (?) mit unbekannter Suchspalte
von: Joerschi
Geschrieben am: 17.07.2015 10:30:09
Danke Dir.
auf den ersten Blick bisschen verwirrend, aber funktioniert :-)
Liebe Grüße
Joerschi

Bild

Betrifft: eine Alternative geht noch? ...
von: der neopa C
Geschrieben am: 17.07.2015 11:16:46
Hallo joerschi,
... eine analog zum Vorschlag von Rudi; nur einfach mit SUMMENPRODUKT()

=SUMMENPRODUKT((INDEX(B5:Z99;;VERGLEICH(B2;4:4;)-1)>=B1)*(INDEX(B5:Z99;;VERGLEICH(C2;4:4;)-1)>=B1)) 
Gruß Werner
.. , - ...

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Zählenwenn (?) mit unbekannter Suchspalte"