Datum

Titel

19.04.2024 17:05:40

Zählen von Zeilen, in denen in bestimmten Bereich Daten sind

19.04.2024 16:34:52

gemeinsamer Filter über drei Spalten

19.04.2024 15:39:42

Exceltabelle daten per combobox zu word Datei

19.04.2024 14:04:05

PDF per VBA ausgeben - Seitenskalierung

Du findest keine passende Antwort auf Deine Frage?

Stelle Deine Frage in unserem Live-Forum

Archiv - Navigation

1744to1748

Aktuelles Verzeichnis

Verzeichnis Index

Übersicht Verzeichnisse

Vorheriger Thread

Rückwärts Blättern

Nächster Thread

Vorwärts blättern

HERBERS

Excel-Forum (Archiv)

20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender

Rückwärts Blättern

Aktuelles Verzeichnis

Übersicht Verzeichnisse

Vorwärts blättern

Inhaltsverzeichnis

Zählen Wenn mit 2 Kriterienbereichen

Forumthread: Zählen Wenn mit 2 Kriterienbereichen
12 Beiträge zu diesem Forumthread
Anzeige
306 Threads zu ähnlichen Themen
VBA Beispiele zu verwandten Themen

Top 100 Forumthreads

09.03.2020 16:49:54

Manni

Hallo meine Lieben,
Ich hätte mal eine Frage zu folgendem Problem. Gerne würde ich die Anzahl aller Tische mit folgenden Kriterien zählen:
- Es ist ein Tisch
- Zähle wenn D1:E10 ist "" und 0
Wie im Beispiel müssten in dem Fall für Tisch die Anzahl 3 rauskommen.
=ZÄHLENWENNS(A2:A9;G2;D2:E9;""&"")
Leider funktioniert mein Versuch nicht. Habt ihr da eine Idee? Ich nehm auch gerne VBA Lösungen. Danke.
Userbild

Viele Grüße
euer Manni.

12
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 16:58:25

SF
AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 16:59:04

UweD
AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:06:52

Manni
AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:08:56

SF
AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:12:36

Manni
AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:14:15

SF
AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:25:09

Manni
AW: mit SUMMENPRODUKT() von MMULT() ...

09.03.2020 17:27:00

MMULT()
AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:36:12

Daniel
noch ein hinweis

09.03.2020 17:41:25

Daniel
AW: bei Einsatz meines Formelvorschlages ...

09.03.2020 17:55:27

neopa
AW: noch ein hinweis

09.03.2020 18:00:44

Manni

AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 16:58:25

Hola,
ich komme auf 5 Tische.
Wieso 3?
Gruß,
steve1da

AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 16:59:04

UweD

Hi

Results

	A	B	C	D	E	F	G	H
1
2	Tisch			20	80
3	Tisch			100	200		Tisch	6
4	Tisch			25			Stuhl	2
5	Tisch			100
6	Tisch
7	Stuhl
8	Stuhl
9	Stuhl			50	50
10	Stuhl

verwendete Formeln
Zelle	Formel	Bereich	N/A
H3:H4	=SUMMENPRODUKT(($A$2:$A$10=$G3)*($D$2:$E$10<>""))

LG UweD

AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:06:52

Manni

Da habe ich mich wohl etwas falsch ausgedrückt. Es sollen nur Tische gezählt werden, wenn der Boys und Girls Bereich nicht leer ist.
z.B. wird A2 Tisch nur als 1 gezählt.
A5 auch als 1.
A4 als 0.

AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:08:56

Hola,
warum wird A5 als 1 gezählt, obwohl E leer ist? Warum wird A3 nicht gezählt, obwohl D und E gefüllt sind?
Gruß,
steve1da

AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:12:36

Manni

Hey steva1da,
da in dem Fall nur D oder E oder beide befüllt sein müssen, um als 1 gezählt zu werden.
A3 wird natürlich auch als 1 gezählt, wollte nur ein paar Beispiele nennen.
Gruß
Manni

AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:14:15

Hola,
man sollte dann schon die wirklich gewünschten Ergebnisse zeigen, nicht nur Beispiele ;-)

=SUMMENPRODUKT(($A$2:$A$10=G2)*($D$2:$D$10"")*($E$2:$E$10""))

=ZÄHLENWENNS($A$2:$A$10;G2;$D$2:$D$10;"";$E$2:$E$10;"")

Gruß,
steve1da

AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:25:09

Manni

Das nächste mal denke ich dran. Danke.
Leider wird mit deiner Formel der 5. Tisch nicht mitgezählt, da nur D5 ausgefüllt ist statt beide.
1 von 2 Reicht schon, um als +1 gezählt zu werden.
Gruß
Manni

AW: mit SUMMENPRODUKT() von MMULT() ...

09.03.2020 17:27:00

MMULT()

Hallo Manni,
... folgende Formel in H2:
=SUMMENPRODUKT((MMULT((Tabelle1[[Boys]:[Girls]]&gt0)*(Tabelle1[Spalte1]=G2);{1;1})&gt0)+0)
und nach unten kopieren.
gibt es als Ergebnis 3 und 1
Gruß Werner
.. , - ...

AW: Zählen Wenn mit 2 Kriterienbereichen

09.03.2020 17:36:12

Daniel

Hi
ZählenWenns und eine ODER-Verknüpfung von zwei spalten funktioniert nicht.
mit ZählenWenns wird die Formel etwas aufwendig, weil du die Anzahl für beide Spalten getrennt ermitteln und adddieren musst, aber dann die doppelt gezählten Zeilen wieder abziehen musst:

=ZÄHLENWENNS($A$2:$A$10;G2;$D$2:$D$10;">0")+ZÄHLENWENNS($A$2:$A$10;G2;$E$2:$E$10;">0") -ZÄHLENWENNS($A$2:$A$10;G2;$D$2:$D$10;">0";$E$2:$E$10;">0")

mit Summenprodukt lässt sich die ODER-Verknüpfung etwas einfacher darstellen:

=SUMMENPRODUKT(($A$2:$A$10=G2)*(($D$2:$D$10+$E$2:$E$10)>0))

Gruß Daniel

noch ein hinweis

09.03.2020 17:41:25

Daniel

für die Verwendung der Summeproduktvariante müssen Zahlen in den Spalten D und E stehen.
sollte dort eine Formel stehen, welche ggf das Ergebnis "Leerstring" ("") haben kann, funtkioniert das nicht so einfach, weil für die durchgeführte Addition der Leerstring nicht in eine Zahl gewandelt werden kann.
in diesem Fall wird die Formel etwas aufwendiger:

=SUMMENPRODUKT(($A$2:$A$10=G2)*((ISTZAHL($D$2:$D$10)+ISTZAHL($E$2:$E$10))>0))

Gruß Daniel

AW: bei Einsatz meines Formelvorschlages ...

09.03.2020 17:55:27

neopa

Hallo Manni,
... müsstest Du in so einem Fall, wie von Daniel zuletzt hier angenommen, in de Formel das "@gt0" lediglich durch """" ersetzen.
Im weiteren sei angemerkt: Da aus Deinem Bild für mich ersichtlich war, dass höchstwahrscheinlich Deine Datenquelle eine "formatierte" Tabelle ist, hab ich als deren Namen: "Tabelle1" angenommen, den Excel automatisch stets für eine 1. "formatierte" Tabelle innerhalb einer Arbeitsmappe vergibt. Sollte es ein anderer Name sein, müsstest Du den Namen in meiner Formel entsprechend dem anpassen.
Gruß Werner
.. , - ...

AW: noch ein hinweis

09.03.2020 18:00:44

Manni

Super,
Vielen Dank für die Formeln und der ausführlichen Erklärung.
Viele Grüße
Manni